sed - 使用 N 命令时，正则表达式地址范围匹配范围外的行

Question

问题描述：

考虑下面的 XML 文件：

<xmlhead1>
   <xmlsubhead1>
       <record>
           <field>Hello</field>
           <field>World</field>
       </record>
       <record>
           <field>DELETEKEY</field>
           <field>World1</field>
       </record>
   </xmlsubhead1>
</xmlhead1>

我的目标是删除一个“记录”XML标签，当字段子标签 该 XML 节点的 包含 DELETEKEY 作为值。

所以在上面的 XML 文件中我将删除

   <record>
       <field>DELETEKEY</field>
       <field>World1</field>
   </record>

选择的解决方案： 我尝试使用 GNU sed 来解决上述问题：
下面是我的代码。

sed -n '

/<xmlhead1>/,/<\/xmlhead1>/{
    /<xmlsubhead1>/,/<\/xmlsubhead1>/{
        /<record>/,/<\/record>/{

            #Append to hold space
            H

            #if match DELETEKEY, start delete processing for the xml <record> element
            /<field>DELETEKEY<\/field>/{
                s/.*//g ; x
                b delete
            }

            #if you have reached the end tag of the <record> element,
            #print the hold space and clear the buffers
            /<\/record>/{
                g ; s/^\n//g; p
                s/.*//g ; x ; s/.*//g
            }

            #continue to next line
            b

            #delete processing
            :delete
            {
                #clear pattern space.
                s/.*//g

                #Read Next Line and remove new line(\n)
                N
                s/^\n//g

                #end delete processing when line matches the end tag </record>
                /<\/record>/b

                #else continue to get next line for delete process
                b delete
            }
        }
    }
}

#print all other lines
p

' $inputfile

逻辑如下：

1. 匹配以<xmlhead1> and ending with </xmlhead1>开头的地址范围
2. 匹配内部地址范围以 <xmlsubhead1> and ending with </xmlsubhead1>
3. 匹配内部地址范围<record> to </record>
4. 当在<record>标签内时，
   (i) 将所有行追加到保持空间。
   (ii) 如果该行匹配DELETEKEY，则必须删除该记录。执行步骤 iii 和 iv。否则，如果没有匹配，请转到步骤 v
   (iii)对于delete，清空hold space并跳转到delete分支
   (iv) 在删除分支中，使用“N”命令读取所有下一行，直到遇到</record>。当</record> 是 遇到，退出循环，开始处理下一个 线。
   (v) 不处理删除逻辑时，如果遇到</record>，则表示<record> to </record>的块是 已成功处理并存在于保留空间中。
   (vi) 所以把它从存放空间中取出并打印出来。

上述逻辑的输出：

<xmlhead1>
   <xmlsubhead1>
       <record>
           <field>Hello</field>
           <field>World</field>
       </record>
</xmlhead1>

输出中的问题：
您会注意到带有 DELETEKEY 的记录元素已被删除，但输出中缺少 </xmlsubhead1> 标记。

问题调试：
在调试时我发现在删除处理中遇到</record> 行后，在<record> to </record> 范围内，内部地址范围匹配应该已经结束，因为我已经读取并处理了</record> 行。

但<record> to </record> 范围块似乎也处理</xmlsubhead1> 行。

我通过在<record> 范围的命令块中添加以下代码发现了这一点。

/<record>/,/<\/record>/{

    /<\/recordList>/{
        s/.*/record list is inside the record to record range/g
        p
    }

有人可以解释 sed 的这种行为，即范围匹配超出了实际匹配吗？在这种情况下<record> to </record> range match is also matching </xmlsubhead1>

Answer 1

不要使用 sed 来编辑 XML，使用 XML 感知工具。比如xsh，可以写：

open file.xml ;
delete //record[field="DELETEKEY"] ;
save :b ;

Answer 2

我同意 cmets 关于使用适当的 XML 解析器的观点。

您的 sed 脚本的问题在于您在 :delete“函数”中读取了 (N) 行。这是一个使用更简单逻辑的工作示例：

/<xmlhead1>/,/<\/xmlhead1>/{
  /<xmlsubhead1>/,/<\/xmlsubhead1>/{
    /<record>/ {
      :a
      N
      /<\/record>/!ba
      /<field>DELETEKEY<\/field>/d
    }
  }
}
p

即在正确的上下文中，读取完整的记录（假设简化的 XML 结构），如果记录包含违规文本，则将其删除。