修改文本文件最后一行中的特定字段

Question

我正在尝试确定是否有一个快速的单行 sed 或 awk 脚本可以执行以修改文本文件中的某个值，特别是文件最后一行中的值。

目前我的文件有一个尾行，其中包含数据行数。我想修改它，使其包含包括页眉和页脚在内的计数。任何帮助将不胜感激。

file1 代码：

H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|38|1208004|1
T|3

修改后的输出应该是

H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|38|1208004|1
T|5

Answer 1

修改以T开头的行：

$ awk '{sub(/^T.*/,"T|"NR)}1' file
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|38|1208004|1
T|5

按照最初的要求修改输入文件的最后一行：

$ awk '{printf "%s",p} {p=$0 ORS} END{sub(/\|.*/,"|"NR,p); print p}' file
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|38|1208004|1
T|5

由于在 cmets 中存在一些争论，为什么我对发布在 here 的 getline 解决方案投了反对票，并且因为很难在 cmets 中给出示例 - 这里有几个示例说明您为什么不应该使用 getline 解决方案（或任何类似的）这个问题（或任何类似的）：

适用于一组输入：

$ cat file1
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|28|1208004|1
T|3

$ awk '{printf "%s",p} {p=$0 ORS} END{sub(/\|.*/,"|"NR,p); print p}' file1
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|28|1208004|1
T|5

$ awk '{l=$0; if(getline==1){print l; print} else {sub("\\|.*","|"NR);print}}' file1
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|28|1208004|1
T|5

另一个失败：

$ cat file2
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
T|3

$ awk '{printf "%s",p} {p=$0 ORS} END{sub(/\|.*/,"|"NR,p); print p}' file2
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
T|4

$ awk '{l=$0; if(getline==1){print l; print} else {sub("\\|.*","|"NR);print}}' file2
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
T|3

尴尬（充其量）以增强最小的工作，例如将每一行打印到 stderr 以进行调试：

$ awk '{print |"cat>&2"} {printf "%s",p} {p=$0 ORS} END{sub(/\|.*/,"|"NR,p); print p}' file2

$ awk '{print |"cat>&2"; l=$0; if(getline==1){print |"cat>&2"; print l; print} else {print |"cat>&2"; sub("\\|.*","|"NR); print}}' file1

请注意修改 2 个版本在简单性上的区别。修改getline 版本是笨拙的、复杂的、不平凡的、不明显的、低效的、容易出现潜在错误、需要重复代码和/或大量重写等...

我们在上面看到的是尝试使用getline 来解决 awk 的自然文本处理模式可以轻松处理的问题的非常常见的后果。

getline 在适当使用时很有用，请参阅http://awk.info/?tip/getline 了解一些有效应用程序的示例。

Answer 2

严格来说，它不是单行的，它对“T”行的格式做出了假设，但是：

(sed '${=;d;}' | sed '$s/^/T|/') < infile > outfile

还有一个 awk 单行：

awk '/^T/ {sub(/[0-9]*$/, NR)}; {print}' < infile > outfile

Answer 3

更新 2：

• 此解决方案有效并且高效因为它只读取输入文件一次。
• 但是，对于更惯用的 awk 解决方案，也只读取一次文件，请参阅 @Ed Morton's answer。
• 此解决方案使用getline，这是一个awk 函数，它有很多陷阱（但也有合法的应用程序） - 请参阅http://awk.freeshell.org/AllAboutGetline
  • 恰当的例子：这个答案的原始版本从根本上被破坏了，因为它只适用于具有 odd 行数的输入文件；再次查看 Ed 的回答以获取说明。
• 通常会使基于getline 的解决方案出现问题的另一个方面是可维护性 - 修改此解决方案以做更多的事情而不仅仅是更新行数会很麻烦。

---

一个只读取输入文件的awk 解决方案一次：

awk '{l=$0; while(getline==1){print l;l=$0;} sub("\\|.*","|"NR); print}' file

注释版：

awk '
  {
    l=$0                     # save 1st line read
    # Start a loop that reads all remaining lines.
    # Print them EXCEPT for the LAST one.
    while (getline == 1) {   # loop until the last line is read
      print l                # print the saved line now known not to be the last
      l=$0                   # save this line for the next iteration
    }
    # Getting here means: the last line was read (and is stored in $0).
    sub("\\|.*","|"NR)       # replace the part after "|" with the line count
    print                    # output modified last line
  }
  ' file

请注意，POSIX awk 和许多实现不支持就地修改输入文件，因此您必须将输出（至少暂时）保存到不同的文件。 p>

但是，正如@Ed Morton 指出的那样，GNU awk，4.1 或更高版本，确实允许使用 -i inplace 进行就地修改 - 请参阅 http://www.gnu.org/software/gawk/manual/gawk.html#Extension-Sample-Inplace

Answer 4

awk 版本

awk -F\| 'FNR==NR{f++;next} FNR==f {$NF=f} 1' OFS=\| file{,}
H|ACCT|XEC|1|TEMP|20130215035845|
D|849002|48|1208004|1
D|849007|28|1208004|1
D|849007|38|1208004|1
T|5

如果file{,}不起作用，请使用file file两次读取文件。 第一次计算行数，然后更新计数器以显示正确的行。

---

只计算以H D 和T 开头的行

awk -F\| 'FNR==NR{if (/^(H|D|T)/) f++;n=NR;next} FNR==n {$NF=f} 1' OFS=\| file{,}