如何将逗号分隔值拆分为多行？

Question

我正在尝试将多个以逗号分隔的值拆分为行。

我已经在少量使用逗号分隔值的列中实现了它（使用awk），但在我的真实表中，我必须在 80 列中完成。所以，我正在寻找一种迭代方式。

我需要拆分的输入示例：

CHROM  POS REF  ALT   GT_00  C_00  D_OO  E_00 F_00  GT_11 
 chr1  10   T    A     2,2   1,1   0,1   1,2   1,0   2
 chr1  10   T    G     3      2     1     2     0    0

预期输出：

chr1  10    T    A     2      1     0     1     1   2
chr1  10    T    A     2      1     1     2     0   2
chr1  10    T    G     3      2     1     2     0   0

我已经用下面的代码做到了：

 awk 'BEGIN{FS=OFS="\t"}
  {
    j=split($5,a,",");split($6,b,",");
    split($7,c,",");split($8,d,",");split($9,e,",");
    for(i=1;i<=j;++i)
    {
      $5=a[i];$6=b[i];$7=c[i];$8=d[i];$9=e[i];print
    }}'

但是，正如我之前所说，在我的真实数据中有 80 列（或更多）具有逗号分隔的值。

有没有办法使用迭代？

注意：我需要在 bash 中完成（不是 MySQL、SQL、python...）

Answer 1

这个awk 可能会：

文件：

chr1    10      T       A       2,2     1,1     0,1     1,2     1,0     2
chr1    10      T       G       3       2       1       2       0       0
chr1    10      T       C       5       1,2,3   4,2,1   7       1,8,3   3
chr1    10      T       D       1,2,3,5 4,2,1,8 1,8,3,2 3       5       7

解决方案：

awk '{
    n=0;
    for(i=5;i<=NF;i++) {
        t=split($i,a,",");if(t>n) n=t};
    for(j=1;j<=n;j++) {
        printf "%s\t%s\t%s\t%s",$1,$2,$3,$4;
        for(i=5;i<=NF;i++) {
            split($i,a,",");printf "\t%s",(a[j]?a[j]:a[1])
            };
        print ""
        }
    }' file
chr1    10      T       A       2       1       0       1       1       2
chr1    10      T       A       2       1       1       2       1       2
chr1    10      T       G       3       2       1       2       0       0
chr1    10      T       C       5       1       4       7       1       3
chr1    10      T       C       5       2       2       7       8       3
chr1    10      T       C       5       3       1       7       3       3
chr1    10      T       D       1       4       1       3       5       7
chr1    10      T       D       2       2       8       3       5       7
chr1    10      T       D       3       1       3       3       5       7
chr1    10      T       D       5       8       2       3       5       7

您的测试输入给出：

chr1    10      T       A       2       1       0       1       1       2
chr1    10      T       A       2       1       1       2       1       2
chr1    10      T       G       3       2       1       2       0       0

逗号分隔的值是否连续无关紧要，只要您不在同一行中混合使用 2 个或 3 个逗号即可。

Answer 2

这是另一个 awk。与之前将字段拆分为数组的解决方案相比，我们使用替换以不同方式解决问题。没有进行字段迭代：

awk '
BEGIN { OFS="\t" }
     { $1=$1;t=$0; }
     { while(index($0,",")) {
         gsub(/,[[:alnum:],]*/,""); print;
         $0=t; gsub(OFS "[[:alnum:]]*,",OFS); t=$0;
       }
       print t
     }' file

它是如何工作的： 这个想法基于两种类型的替换：

1. gsub(/,[[:alnum:],]*/,""): 这将删除所有由字母数字字符和以逗号开头的逗号组成的子字符串：1,2,3,4 -> 1。这不会更改没有逗号的字段。
2. gsub(OFS "[[:alnum:]]*,",OFS): 这将删除字母数字字符后跟一个逗号并位于字段开头：1,2,3,4 -> 2,3,4

所以使用这两个替换，我们迭代直到没有逗号。有关[[:alnum:]] 的详细信息，请参阅How can you tell which characters are in which character classes?

输入：

chr1    10      T       A       2,2     1,1     0,1     1,2     1,0     2
chr1    10      T       G       3       2       1       2       0       0
chr1    10      T       C       5       1,2,3   4,2,1   7       1,8,3   3
chr1    10      T       D       1,2,3,5 4,2,1,8 1,8,3,2 3       5       7

输出：

chr1    10  T   A   2   1   0   1   1   2
chr1    10  T   A   2   1   1   2   0   2
chr1    10  T   G   3   2   1   2   0   0
chr1    10  T   C   5   1   4   7   1   3
chr1    10  T   C   5   2   2   7   8   3
chr1    10  T   C   5   3   1   7   3   3
chr1    10  T   D   1   4   1   3   5   7
chr1    10  T   D   2   2   8   3   5   7
chr1    10  T   D   3   1   3   3   5   7
chr1    10  T   D   5   8   2   3   5   7