在 F# 中打印树列表元组元素

Question

我有一个像这样的简单树结构..

type Tree<'a,'b> = 
    | Node of list<'a * Tree<'a,'b>>
    | Leaf of 'b

let phonebook = Node["MyPhonebook",
                     Node["Work",
                          Node["Company1", Node["Employee1", Leaf("phone#")];
                               "Company2", Leaf("phone#")];
                          "Private",
                          Node["Family", Node["Brother", Leaf("phone#");]; "Sister", Leaf("phone#")]
                         ]
                    ]

我只是想打印此电话簿的根文件夹（工作、私人），但无论我做什么似乎都无法正确...

let listelements tree =
    match tree with
    | Node[a, b] -> // OK - root node
        printfn "%s" a // OK - root folder name
        match b with
        //| _ -> printf "%A" b // OK - prints whole node
        | Node[a, b] -> printf "%A" a // Match failure!

listelements phonebook

在那之后，我意识到我一直在将元组与列表匹配，所以我尝试了一些不同的方法，但我又遇到了不匹配问题。

let phonebook = [Node["Work",
                      Node["Company1", Node["Employee1", Leaf("phone#")];
                           "Company2", Leaf("phone#")];
                      "Private",
                      Node["Family", Node["Brother", Leaf("phone#");]; "Sister", Leaf("phone#")]
                     ]
                 ]

let listelements tree =
    for i in tree do
        match i with
        | Node[a, b] -> printf "%s" a // Match fail

let listelements tree =
    //tree |> List.iter (fun x -> printf "%A" x) // OK - prints nodes
    tree |> List.iter (fun x ->
        match x with
        | Node[a, b] -> printf "%A" a) // Match fail

我到底做错了什么？必须有一种更优雅、更简单的方法来做到这一点。我来自 C#，这让我发疯：P

Answer 1

您正在将单个元素（元组）的列表与列表进行匹配，因此在第一种情况下，列表仅包含一个元素，并且它通过编译器警告您匹配不完整。 但是在第二个匹配中，列表包含两个元组，所以它失败了。

改用 head::tail 模式，如下所示：

| Node((a, b)::xs)

或者如果你对尾巴完全不感兴趣：

| Node((a, b)::_)

注意

有助于澄清代码的内容：树是定义中的元组列表。如果您编写使元组的括号显式的模式会更好，我的意思是如果您编写：

| Node[(a, b)] -> 

而不仅仅是

| Node[a, b] -> 

这里编译器理解这是一个元组，但人类可能不知道，特别是如果它来自 Haskell 背景。

因此，编写括号可能会帮助您找出问题在于您要再次匹配一个只有一个元组的列表。

更新

如果你想使用List.iter打印所有元素：

let rec listelements tree =
    let printNode (a, b) = 
        printfn "%s" a
        listelements b
    match tree with
    | Leaf leaf         -> printfn "Leaf %s" leaf
    | Node(listOfNodes) -> List.iter printNode listOfNodes