如何合并地图并获取列表地图？

Question

假设我们是一张地图列表。地图都有相同的关键字，但我们事先并不知道关键字。

[{:a 1 :b 2} {:a 3 :b 4}]

以及将这个列表合并到这样一个地图中的惯用方式是什么：

{:a [1 3]
 :b [2 4]}

看起来并不难，但是当我开始实现该功能时，它变得超级丑陋和重复。我有一种感觉，有更清洁的方法可以实现这一目标。

谢谢

Answer 1

您实际上可以通过使用标准库中的几个函数来获得一个非常优雅的解决方案：

(defn consolidate [& ms]
  (apply merge-with conj (zipmap (mapcat keys ms) (repeat [])) ms))

例子：

(consolidate {:a 1 :b 2} {:a 3 :b 4})
;=> {:a [1 3], :b [2 4]}

这个解决方案的一个很酷的地方是，即使地图具有不同的键集，它也能正常工作。

Answer 2

我宁愿使用双重减少将它们与update“合并”：

(defn merge-maps-with-vec [maps]
  (reduce (partial reduce-kv #(update %1 %2 (fnil conj []) %3))
          {} maps))

user> (merge-maps-with-vec [{:a 1 :b 2} {:a 3 :b 4 :c 10}])
{:a [1 3], :b [2 4], :c [10]}

它不像@Sam Estep 的答案那样富有表现力，但另一方面它不会生成任何中间序列（例如每个键到空向量映射，它还需要通过每个地图）。当然，过早的优化通常是不好的，但我想它不会在这里受到伤害。虽然基于 reduce 的解决方案看起来有点晦涩难懂，但如果将其放入带有适当文档的库中，最终用户（或一年后的您自己）不会觉得它晦涩难懂

Answer 3

虽然有许多解决方案是可能的，但这里有一个使用一些便利功能in the Tupelo library：

(ns clj.core
  (:use tupelo.core)
  (:require [tupelo.schema :as ts]
            [schema.core :as s] ))

(s/defn gather-keys
  [list-of-maps :- [ts/KeyMap]]
  (newline)
  (let [keys-vec (keys (first list-of-maps))]
    (s/validate [s/Keyword] keys-vec) ; verify it is a vector of keywords
    (apply glue
      (for [curr-key keys-vec]
        {curr-key (forv [curr-map list-of-maps]
                    (get curr-map curr-key))} ))))
(deftest t-maps
  (spyx
    (gather-keys [{:a 1 :b 2}
                  {:a 3 :b 4} ] )))

(gather-keys [{:a 1, :b 2} {:a 3, :b 4}]) ;=> {:a [1 3], :b [2 4]}

请注意，此解决方案假设每个输入映射都有一组相同的键。通常我也想通过代码中的健全性检查来强制执行该假设。

看着 Sam 的答案，我会用一些临时变量重写它以帮助记录子步骤：

(defn consolidate-keys [list-of-maps]
  (let [keys-set     (set (mapcat keys list-of-maps))
        base-result  (zipmap keys-set  (repeat [] )) ]
    (apply merge-with conj base-result list-of-maps)))

(consolidate-keys  [ {:a 1 :b 2}
                     {:a 3 :z 9} ] )
;=> {:z [9], :b [2], :a [1 3]}