将数字列表转换为数字

Question

我想知道是否有办法获取一个数字列表（数字），并将这些数字截断成一个大数字（不是加法）。例如，我想要

(foo '(1 2 3 4))
;=> 1234

Scheme 有内置函数吗？

Answer 1

Scheme 系列中有多种语言，Scheme 也有几个版本。如果您使用的是一个，例如，球拍，它包括一个左关联折叠（通常称为foldl、fold 或reduce，尽管也有其他变体），这很容易实现的折叠。这些问题和答案中更详细地描述了折叠：

• Finding maximum distance between two points in a list (scheme) 这个问题包括对如何将fold 视为迭代构造的描述（并且在要求尾调用优化的Scheme 中，它被编译为迭代代码），还包括foldl 用于Scheme 的实现没有。
• Flattening a List of Lists这个问题是关于一个有点不寻常的折叠，以及如何使用它（或标准折叠）来展平列表。
• scheme structures and lists 这个问题有一个示例，说明如何调整传递给折叠的函数以实现稍微不同的行为。 （我还包括一个固执己见的（但真实的；），我向你保证）关于 Common Lisp 的 reduce 如何提供比某些 Scheme 库中提供的更方便的界面的评论。

这是foldl 的代码：

(define (list->num digits)
  (foldl (lambda (digit n)
           (+ (* 10 n) digit))
         0
         digits))

> (list->num '(1 2 3 4))
1234 

如果您的语言没有，foldl 很容易编写（例如，my answer to the one of the questions above 包含一个实现）并使用前面的代码，或者您可以编写整个函数（使用相同的方法）你自己：

(define (list->num-helper digits number-so-far)
  (if (null? digits)
      number-so-far
      (list->num-helper (cdr digits)
                        (+ (* 10 number-so-far)
                           (car digits)))))

(define (list->num digits)
  (list->num-helper digits 0))

您可以使用命名let 使其更简洁：

(define (list->num digits)
  (let l->n ((digits digits)
             (number 0))
    (if (null? digits)
        number
        (l->n (cdr digits)
              (+ (* 10 number)
                 (car digits))))))