Excel VBA Dir() 文件类型更改时出错

Question

我试图更好地理解Dir 函数。我有一个Dir 循环来对目录中的所有.csv 文件执行操作，但是当循环遇到另一种文件类型（如.txt）时，它会出错而不是转到下一个.csv。物品。

这是我的代码的相关部分。

strSourceExcelLocation = "\\rilinfs001\Interdepartmental\Billings & Deductions\Billing Coordinators\MCB Reports\East\Monthly Quality MCBs (CMQ & SECMQ)\2019\Individual_Reports\" & fldr & "\"

strWorkbook = Dir(strSourceExcelLocation & "*.csv*")

Do While Len(strWorkbook) > 0
    'Open the workbook
    Set wbktoExport = Workbooks.Open(Filename:=strSourceExcelLocation & strWorkbook)

    'Export all sheets as single PDF
    Call Export_Excel_as_PDF(wbktoExport)

    'Get next workbook
    strWorkbook = Dir

    'Close Excel workbook without making changes
    wbktoExport.Close False
Loop

因此，如果目录中只有 .csv 文件，那么这可以正常工作。当它遇到另一种文件类型时，就会发生错误。

错误在线

strWorkbook = Dir

运行时错误 5：无效的过程调用或参数

我在开头使用.csv 中的通配符的方式是否遗漏了什么？

谢谢

Answer 1

解决了我的问题。

问题似乎是因为当我调用另一个程序时，我在该子程序中有另一个Dir 来创建一个新文件夹（如果该文件夹尚不存在）。所以基本上我在Dir 中有一个Dir，这显然很糟糕。

我将文件夹创建部分移到了我的程序的最开始，因此它在我开始 Dir 循环所有 CSV 文件之前执行。

Option Explicit

Sub Loop_Dir_for_Excel_Workbooks()
Dim strWorkbook As String, wbktoExport As Workbook, strSourceExcelLocation As String, fldr As String, strTargetPDFLocation As String, d As String

strTargetPDFLocation = "\\nhchefs001\Accounting\IMAGING\BILLINGS & DEDUCTIONS\EAST MCB FILES\"
'***** Creating a folder to save the PDFs in. Naming the folder with today's date *****
d = Format(Date, "mm-dd-yyyy")
strTargetPDFLocation = "\\nhchefs001\Accounting\IMAGING\BILLINGS & DEDUCTIONS\EAST MCB FILES\" & d & "\"
If Len(Dir(strTargetPDFLocation, vbDirectory)) = 0 Then MkDir strTargetPDFLocation

fldr = InputBox("Input the EXACT Folder Name that you want to create PDFs for")

strSourceExcelLocation = "\\rilinfs001\Interdepartmental\Billings & Deductions\Billing Coordinators\MCB Reports\East\Monthly Quality MCBs (CMQ & SECMQ)\2019\Individual_Reports\" & fldr & "\"

'Search all Excel files in the directory with .xls, .xlsx, xlsm extensions
strWorkbook = Dir(strSourceExcelLocation & "*.csv")

Do While Len(strWorkbook) > 0
    'Open the workbook
    Set wbktoExport = Workbooks.Open(Filename:=strSourceExcelLocation & strWorkbook)

    'Export all sheets as single PDF
    Call Export_Excel_as_PDF(wbktoExport, strTargetPDFLocation)

    'Close Excel workbook without making changes
    wbktoExport.Close False

    'Get next workbook
    strWorkbook = Dir

Loop

End Sub

Answer 2

尝试对路径进行硬编码，然后再试一次。可能错误在硬编码中非常小。例如，在下面的代码中，将C:\Users\username\Desktop\AAA\ 替换为文件的路径。然后运行它。不要忘记最后一个\。它应该工作：

Sub TestMe()

    Dim workbookPath As String
    workbookPath = Dir("C:\Users\username\Desktop\AAA\" & "*.csv")

    Do While Len(workbookPath) > 0
        Debug.Print workbookPath
        workbookPath = Dir
    Loop

End Sub