Perl正则表达式匹配特殊字符

Question

我在下面的代码中检查排除的数组中的特定变量位置。它适用于除一个以外的所有数组元素 (abc/def/libraries/linux_3.2.60-1+deb7u3.dsc) .当我提供这个元素作为我的位置时，它的打印“位置不排除”，即使它被排除在外。

我怎样才能让我的代码得到这个元素以及排除？

use strict;
use warnings;

my @excluded = (
 "xyz/efg/headers/",
 "abc/def/libraries/jni-mr.h",
 "abc/def/libraries/linux_3.2.60-1+deb7u3.dsc", 
);

my $location = "abc/def/libraries/linux_3.2.60-1+deb7u3.dsc";
my $badpath = 0;

foreach (@excluded) {
    # -- Check if location is contained in excluded array
    if ($location =~ /^$_/) {
       $badpath = 1;
       print "location is excluded : $location \n";
     }
   }

   if (! $badpath) {
      print "location is not excluded : $location \n";  
     }

期望的输出：

location is excluded : abc/def/libraries/linux_3.2.60-1+deb7u3.dsc

电流输出：

location is not excluded : abc/def/libraries/linux_3.2.60-1+deb7u3.dsc

Answer 1

使用quotemeta($text) 或\Q$text\E（在双引号或正则表达式文字内）创建与$text 的值匹配的模式。换句话说，使用

if ($location =~ /^\Q$_\E/)

代替：

if ($location =~ /^$_/)

Answer 2

• 您似乎打算通过正则表达式定义排除项，但您没有在这些正则表达式中正确转义正则表达式元字符。对于您的失败案例，导致它失败的元字符是加号 (+)，这是大多数正则表达式风格（包括 Perl）中的一个或多个乘数，但您需要逐字匹配。

• 另外，我建议将 ^ 锚从循环移动到每个单独的正则表达式，这将使代码更加灵活，因为如果你愿意，你可以选择不锚定一些排除正则表达式.

• 此外，您应该使用 qr() 构造，它允许您预编译正则表达式，从而节省 CPU。

• 此外，此要求非常适合使用 grep()。

---

use strict;
use warnings;

my @excluded = (
    qr(^xyz/efg/headers/),
    qr(^abc/def/libraries/jni-mr\.h),
    qr(^abc/def/libraries/linux_3\.2\.60-1\+deb7u3\.dsc),
);

my $location = 'abc/def/libraries/linux_3.2.60-1+deb7u3.dsc';

# -- Check if location is contained in excluded array
my $badpath = scalar(grep($location =~ $_, @excluded )) >= 1 ? 1 : 0;
if ($badpath) {
    print "location is excluded : $location \n";
} else {
    print "location is not excluded : $location \n";
}