如何保留awk中字段之间的原始空白？

Question

使用awk 处理输入时，有时我想编辑其中一个字段，而不涉及其他任何内容。考虑一下：

$ ls -l | awk 1
total 88
-rw-r--r-- 1 jack jack     8 Jun 19  2013 qunit-1.11.0.css
-rw-r--r-- 1 jack jack 56908 Jun 19  2013 qunit-1.11.0.js
-rw-r--r-- 1 jack jack  4306 Dec 29 09:16 test1.html
-rw-r--r-- 1 jack jack  5476 Dec  7 08:09 test1.js

如果我不编辑任何字段（$1、$2、...），所有内容都会保持原样。但如果假设我只想保留第一个字段的前 3 个字符：

$ ls -l | awk '{$1 = substr($1, 1, 3) } 1'
tot 88
-rw 1 jack jack 8 Jun 19 2013 qunit-1.11.0.css
-rw 1 jack jack 56908 Jun 19 2013 qunit-1.11.0.js
-rw 1 jack jack 4306 Dec 29 09:16 test1.html
-rw 1 jack jack 5476 Dec 7 08:09 test1.js

所有字段之间的原始空白被替换为一个简单的空格。

有没有办法保留字段之间的原始空白？

更新

在此示例中，编辑前 4 个字段相对容易。但是，如果我只想保留 $5 的第一个字母以获得此输出：

-rw-r--r-- 1 jack jack     8 J 19  2013 qunit-1.11.0.css
-rw-r--r-- 1 jack jack 56908 J 19  2013 qunit-1.11.0.js
-rw-r--r-- 1 jack jack  4306 D 29 09:16 test1.html
-rw-r--r-- 1 jack jack  5476 D  7 08:09 test1.js

Answer 1

如果你想保留空格，你也可以试试split 函数。 在 Gnu Awk 版本 4 中，split 函数接受 4 个参数，其中后者是字段之间的分隔符。例如，

echo "a  2   4  6" | gawk ' {
 n=split($0,a," ",b)
 a[3]=7
 line=b[0]
 for (i=1;i<=n; i++)
     line=(line a[i] b[i])
 print line
}' 

给出输出

a  2   7  6

Answer 2

我知道这是一个老问题，但我认为必须有更好的东西。这个答案适用于那些在搜索时偶然发现这个问题的人。在网上浏览时，我不得不说@Håkon Hægland 有最好的答案，这就是我最初使用的。

但这是我的解决方案。使用FPAT。它可以设置一个正则表达式来说明一个字段应该是什么。

 FPAT = "([[:space:]]*[[:alnum:][:punct:][:digit:]]+)";

在这种情况下，我是说该字段应该以零个或多个空白字符开头，并且基本上以除空白字符之外的任何其他字符结尾。如果您在理解 POSIX 括号表达式时遇到困难，Here 是一个链接。

另外，将输出字段更改为OFS = ""; 分隔符，因为一旦对行进行了操作，如果您不更改默认的 OFS，输出将添加一个额外的空格作为分隔符。

我用同样的例子来测试。

$ cat example-output.txt
-rw-r--r-- 1 jack jack     8 Jun 19  2013 qunit-1.11.0.css
-rw-r--r-- 1 jack jack 56908 Jun 19  2013 qunit-1.11.0.js
-rw-r--r-- 1 jack jack  4306 Dec 29 09:16 test1.html
-rw-r--r-- 1 jack jack  5476 Dec  7 08:09 test1.js

$ awk 'BEGIN { FPAT = "([[:space:]]*[[:alnum:][:punct:][:digit:]]+)"; OFS = ""; } { $6 = substr( $6, 1, 2);  print $0; }' example-output.txt
-rw-r--r-- 1 jack jack     8 J 19  2013 qunit-1.11.0.css
-rw-r--r-- 1 jack jack 56908 J 19  2013 qunit-1.11.0.js
-rw-r--r-- 1 jack jack  4306 D 29 09:16 test1.html
-rw-r--r-- 1 jack jack  5476 D  7 08:09 test1.js

请记住。这些字段现在有前导空格。因此，如果该字段需要替换为其他内容，您可以这样做

len = length($1); 
$1 = sprintf("%"(len)"s", "-42-");

$ awk 'BEGIN { FPAT = "([[:space:]]*[[:alnum:][:punct:][:digit:]]+)"; OFS = ""; } { if(NR==1){ len = length($1); $1 = sprintf("%"(len)"s", "-42-"); } print $0; }' example-output.txt
      -42- 1 jack jack     8 Jun 19  2013 qunit-1.11.0.css
-rw-r--r-- 1 jack jack 56908 Jun 19  2013 qunit-1.11.0.js
-rw-r--r-- 1 jack jack  4306 Dec 29 09:16 test1.html
-rw-r--r-- 1 jack jack  5476 Dec  7 08:09 test1.js

Answer 3

最简单的解决方案是确保在每个空间上都进行字段拆分。这是通过使字段分隔符[ ]:

$ awk -F '[ ]' '{$1=substr($1,1,3)}1' infile

-rw 1 jack jack     8 Jun 19  2013 qunit-1.11.0.css
-rw 1 jack jack 56908 Jun 19  2013 qunit-1.11.0.js
-rw 1 jack jack  4306 Dec 29 09:16 test1.html
-rw 1 jack jack  5476 Dec  7 08:09 test1.js

---

默认情况下，awk 会在任何重复空格（制表符和空格，类似于[ \t]+）上进行拆分。手册指出：

在 FS 是单个空格的特殊情况下，字段由空格和/或制表符和/或换行符分隔。

这会将空格、制表符和换行符的运行折叠为输出中的一个 OFS 值。如果 OFS 也是一个空格（也是默认值），结果是每次运行的空白只打印一个空格。

但是可以告诉 awk 使用仅匹配 一个 字符的正则表达式选择一个空格作为字段分隔符：[ ]。

请注意，这将更改字段的字段编号。每个空间都会开始一个新的领域。因此，请注意您提供的数据中的以下结果：

$ awk -F '[ ]' '{print($4,$5,$6)}' infile
jack
jack 56908 Jun
jack  4306
jack  5476

在这种特定情况下，第一个字段之前没有空格，之后只有一个空格，这就是它正常工作的原因。

Answer 4

可以通过编辑$0 而不是单个字段（$1、$2、...）来保留原始空格，例如：

$ ls -l | awk '{$0 = substr($1, 1, 3) substr($0, length($1) + 1)} 1'
tot 88
-rw 1 jack jack     8 Jun 19  2013 qunit-1.11.0.css
-rw 1 jack jack 56908 Jun 19  2013 qunit-1.11.0.js
-rw 1 jack jack  4306 Dec 29 09:16 test1.html
-rw 1 jack jack  5476 Dec  7 08:09 test1.js

这在编辑第一列时相对容易做到，但在编辑其他列时会很麻烦（$2，...，$4），并且在中间的空白宽度不是的字段之后分解已修复（在此示例中为$5 及以上）。

更新

根据@Håkon Hægland的回答，这里有一种方法可以保留第6个字段（月份）的前2个字符：

{
    n = split($0, f, " ", sep)
    f[6] = substr(f[6], 1, 2)
    line = sep[0]
    for (i = 1; i <= n; ++i) line = line f[i] sep[i]
    print line
}