我有一个包含以下内容的文件，并且想要删除最后一个逗号（在本例中，是 'c' 和 'f' 之后的逗号）。
heading1(
a,
b,
c,
);
some more text
heading2(
d,
e,
f,
);
这必须使用 bash 而不是 Perl 或 Python 等，因为它们没有安装在我的目标系统上。我可以使用sed、awk 等，但我不能使用带有-z 参数的sed，因为我使用的是旧版本的实用程序。
所以sed -zi 's/,\n);/\n);/g' $file 不在讨论范围内。
任何帮助将不胜感激。谢谢
【问题讨论】：
这可能适用于您的 sed 版本。那么它可能不会。
sed 'x;1d;G;/;$/s/,//;$!s/\n.*//' $file
粗略翻译：“将此行与保留空间交换。如果这是第一行，则不再使用它。将保留空间附加到缓冲区中的行（这样您就可以看到最后一行当前行）。如果您的内容以分号结尾，请删除逗号。如果您不在文件的最后一行，请删除您拥有的两行中的第二行（即当前行，我们将等我们看到下一个后再处理）。”
【讨论】：
使用 awk、RS="^$" 读取整个文件并使用正则表达式替换部分文本：
$ awk -v RS=^$ '{gsub(/,\n\);/,"\n);")}1' file
一些输出：
heading1(
a,
b,
c
);
...
【讨论】：
这应该在显示的输入上与 GNU sed 和 BSD sed 一起使用：
sed -e ':a' -e '/,\n);$/!{N' -e 'ba' -e '}' -e 's/,\n);$/\n);/' file.txt
我们连接模式空间中的行，直到它以,\n); 结尾。然后我们删除逗号，打印（默认）并用新行重新开始循环。
使用 GNU sed 的更简单、更易读的版本（您没有）：
sed ':a;/,\n);$/!{N;ba};s/,\n);$/\n);/' file.txt
【讨论】：
\n 的，我想了解一下。
\n，而此解决方案在替换字符串中使用它。我记得我曾经拥有一个可以处理一个但不能处理另一个的 sed 版本。如果\n 在 sed 脚本中间被替换为实际的换行符，我敢打赌这个解决方案将适用于 OP。 （出于这个原因，我讨厌那个版本的 sed。）
使用awk：
awk '
$0==");" {sub(/,$/, "", l)}
FNR!=1 {print l}
{l=$0}
END {print l}'
【讨论】：
使用sed 大致有两种方法：
只使用模式空间意味着一个非常简洁的版本：
sed 'N; s/,\n*)/)/; P; D'
这依赖于模式空间能够容纳多行，并且能够将换行符与\n 匹配。并非所有版本的 sed 都可以做到这一点，但 GNU sed 可以。
这还依赖于 N、P 和 D 的隐式行为，这些行为会根据何时到达输入结束而变化。阅读man sed了解血腥细节。
展开到每行一个命令得到：
sed '
N
s/,\n*)/)/
P
D
'
如果您只有 POSIX 版本的sed 可用，您还需要使用保留空间。在这种情况下，想法是当您在模式空间中看到 ) 时，您可以编辑保留空间中的行以删除逗号：
sed '1 { h; d; }; /^)/ { x; s/,$//; x; }; x; $ { p; x; s/,$//; }'
展开我们得到：
sed '
1 {
h
d
}
/^)/ {
x
s/,$//
x
}
x
$ {
p
x
s/,$//
}
'
打破它：接下来是一个“sed 脚本”；所以只需在它周围加上 '' 并在它前面加上“sed”：
sed '
首先无条件地将第一行从模式空间复制到保持空间，然后删除模式空间（这会强制跳到下一行）
1 {
h
d
}
对于以 ')' 开头的每一行，交换模式空间和保持空间（因此您现在在模式空间中有前一行），删除尾随逗号（如果有），然后再次交换回来：
/^)/ {
x
s/,$//
x
}
现在将模式空间与保持空间交换，以便保持空间现在保持当前行，而模式空间保持上一行。
x
通常，当到达脚本末尾时，模式空间的内容将被发送到输出，但我们首先要处理另一种情况。
在最后一行，打印上一行，然后交换以检索最后一行，然后（因为我们到达 script0 的末尾也打印它。此代码还将从最后一行删除尾随逗号，但这是可选；如果您不想要，可以将其删除。
$ {
p
x
s/,$//
}
到达 sed 脚本的末尾时，将打印模式空间；所以最后没有“p”。
如前所述，从头开始关闭引用。
'
注意： 如果您需要向前扫描多行，而不是“x”来交换一行，使用“H;g”附加到保留空间，然后将保留空间复制到模式空间，然后“P;D”打印并删除到第一个换行符。 （H、P 和 D 是 GNU 扩展。）
【讨论】：
这可能对你有用（GNU sed）：
sed '/,$/{N;/);$/Ms/,$//M;P;D}' file
如果一行以逗号结尾，则获取下一行，如果以 ); 结尾，则删除逗号。
否则，如果以下行与上述不匹配，则打印/删除第一行并重复。
【讨论】：