xsl 转换删除双标签

Question

我有一些 XML 需要转换以删除双标签。

原来我用的是：

<xsl:template match="*[name()=name(../..)]"></xsl:template>
<xsl:template match="*[name()=name(../../..)]"></xsl:template>
<xsl:template match="*[name()=name(..)]">
    <xsl:apply-templates select="@*|node()"/>
</xsl:template>

它们一起删除了两个同名标签的内部。但这只有在只有一个内部标签时才有效。

我有：

<a>
 <a>
    <b>xxxx</b>
    <c>xxxx</c>
 </a>
 <a>
    <b>yyyy</b>
    <c>yyyy</c>
 </a>
</a>

我想结束：

 <a>
    <b>xxxx</b>
    <c>xxxx</c>
 </a>
 <a>
    <b>yyyy</b>
    <c>yyyy</c>
 </a>

而不是：

 <a>
    <b>xxxx</b>
    <c>xxxx</c>
    <b>yyyy</b>
    <c>yyyy</c>
 </a>

我对 XSL 转换和搜索语法知之甚少，希望有人能帮助我。

Answer 1

以下样式表将删除所有子元素都具有相同名称的 外部（父）元素：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- exception for parent whose children have all the same name -->
<xsl:template match="*[*][not(*[name()!=name(..)])]">
    <xsl:apply-templates select="@*|node()"/>
</xsl:template>

</xsl:stylesheet>

当上述应用于以下测试输入时：

<root>
    <a>
        <a>
            <b>bbb</b>
            <c>ccc</c>
        </a>
        <a>
            <d>
                <d>ddd</d>      
            </d>
            <e>eee</e>
            <f>
                <f>fff</f>  
                <g>ggg</g>  
            </f>
        </a>
    </a>
</root>

结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <a>
      <b>bbb</b>
      <c>ccc</c>
   </a>
   <a>
      <d>ddd</d>
      <e>eee</e>
      <f>
         <f>fff</f>
         <g>ggg</g>
      </f>
   </a>
</root>

Answer 2

与其在孩子的名字与父级匹配时删除它，不如在它的名称与其所有子级相同时删除父级：

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy>
</xsl:template>

<xsl:template match="*[*][not(*[name() != name(..)])]">
  <xsl:apply-templates select="@*|node()" />
</xsl:template>

您可以将第二个匹配表达式解读为“任何元素 X，它至少具有一个子元素，并且没有任何名称不同于 X 的子元素”。