IN 语句中的 dbms_sql.number_table

Question

我已经声明了一个数字表，例如：

v_areas_hijas   dbms_sql.number_table;

我填满表格，然后我正在尝试这个比较：

  select 
  idarea
from areas 
where 
  IDAREAPADRE in v_areas_hijas;

但我得到了：

错误（45,22）：PLS-00382：表达式类型错误

我应该怎么做那个 IN 语句？

编辑 1：使用“成员”

  select 
      idarea
    from areas 
    where 
      IDAREAPADRE member of v_areas_hijas;
  

我有这两个错误：

错误（45,29）：PLS-00382：表达式类型错误

错误（45,29）：PL/SQL：ORA-00932：不一致的数据类型预期 UDT 得到了 CHAR

在AREAS表中，IDAREA和IDAREAPADRE是NUMBER，

Answer 1

在您的other question 中，v_areas_hijas 不是表格。如果它是 SQL 中定义的集合类型，您可以使用 member of 集合运算符：

select idarea bulk collect into v_areas_hijas_tmp 
from   areas 
where  idareapadre member of v_areas_hijas;

例如，使用预定义类型sys.dbms_debug_vc2coll（更多示例请查看all_coll_types），

declare 
    t_demo sys.dbms_debug_vc2coll := sys.dbms_debug_vc2coll('X','Y','Z');
    l_result integer;
begin
    select count(*) into l_result
    from   dual
    where  dummy member of t_demo;

    -- Or this:
    select count(*) into l_result
    from   dual
    where  dummy in
           ( select column_value from table(t_demo) );

    -- Or this:
    select count(*) into l_result
    from   dual d
           join table(t_demo) t on t.column_value = d.dummy;

    dbms_output.put_line(l_result);
end;

您可以在包中声明的嵌套表和可变数组类型上使用table() 运算符：

create or replace package demo
as
    type demo_collection_type is table of varchar2(1);
end demo;

然后

declare 
    t_demo demo.demo_collection_type := demo.demo_collection_type('X','Y','Z');
    l_result integer;
begin
    select count(*) into l_result
    from   dual
    where  dummy in
           ( select column_value from table(t_demo) t );

    dbms_output.put_line(l_result);

    -- Or:
    select count(*) into l_result
    from   dual d
           join table(t_demo) t on t.column_value = d.dummy;

    dbms_output.put_line(l_result);
end;

从 12.1 开始，您不能将 member of 用于 PL/SQL 包中声明的集合类型。

其中一些限制在 12.2 中被取消。