如何确定数组的元素是否与另一个数组的任何元素匹配？

Question

如果我有哈希

my %foo = ( foo => 1, bar => 1 );

我想检查 %foo 的任何键是否在比较数组中（显然键 %foo 只是一个数组）。我一直在想一些不存在的奇怪语法。

my @cmp0 = qw( foo baz    );
my @cmp1 = qw( baz blargh );

if keys %foo in @cmp0 # returns true because key foo is in the array
if keys %foo in @cmp1 # returns false because no key in foo is an element of cmp1

最简单的方法是什么？

Answer 1

List::MoreUtils 有一个名为any 的函数，它使用类似于grep 的语法，但在第一次满足条件时停止其内部循环。这种行为的优点是需要的迭代次数要少得多（假设交叉点的随机分布）。

any 的另一个优点是代码清晰：它以其功能命名。 Perl 最佳实践不鼓励在布尔上下文中使用grep，因为grep 的假定用途是返回匹配的元素列表。它在布尔上下文中工作，但对于读者来说，代码的意图不如 any 清楚，后者专为布尔使用而设计。

any 确实添加了对 List::MoreUtils 的依赖。但是，List::MoreUtils 是无处不在的模块之一，它很可能已经安装了。

这是一个例子：

use List::MoreUtils qw( any );

my %foo = ( foo => 1, bar => 1 );

my @cmp0 = qw( foo baz    );
my @cmp1 = qw( baz blargh );

print "\@cmp0 and %foo have an intersection.\n" 
    if any { exists $foo{$_} } @cmp0;

print "\@cmp1 and %foo have an intersection.\n"
    if any { exists $foo{$_} } @cmp1;

另一个选项是~~Smart Match Operator，它在 Perl 5.10.0 和更新版本中可用。可以这样使用：

my %foo = ( foo => 1, bar => 1 );

my @cmp0 = qw( foo baz    );
my @cmp1 = qw( baz blargh );

print "\@cmp0 and %foo have an intersection.\n" if @cmp0 ~~ %foo;

print "\@cmp1 and %foo have an intersection.\n" if @cmp1 ~~ %foo;

使用 smartmatch，您消除了 List::MoreUtils 依赖，取而代之的是最小的 Perl 版本依赖。代码是否像any一样清晰，由你决定。

Answer 2

最简洁的编写方法是使用grep 和exists 运算符。

这段代码

my %foo = ( foo => 1, bar => 1 );

my @cmp0 = qw( foo baz    );
my @cmp1 = qw( baz blargh );

print "YES 0\n" if grep { exists $foo{$_} } @cmp0;
print "YES 1\n" if grep { exists $foo{$_} } @cmp1;

给出这个输出

YES 0

Answer 3

grep 是个好主意，而且可能是最干净的。但是，您也可以使用logical OR assignment operator ||=:

my $found;
$found ||= exists $foo{$_} for @cmp1;

Answer 4

这些是简单的设置操作。

use strictures;
use Set::Scalar qw();
⋮
my $foo = Set::Scalar->new(keys %foo);
$foo->intersection(Set::Scalar->new(@cmp0))->size; # 1
$foo->intersection(Set::Scalar->new(@cmp1))->size; # 0

Answer 5

像往常一样，有更多方法可以解决这个问题。你可以这样做：

#!/usr/bin/perl

use strict ;
use warnings ;

my %hash = ( foo => 1 , bar => 1 ) ;
my %cmp = ( cmp0 => [ qw(foo baz) ] ,
            cmp1 => [ qw(baz blargh) ] ) ;

my @hash_keys = keys %hash ;
foreach my $compare ( keys %cmp ) {
  my %tmp ;
  # Generate a temporary hash from comparison keys via hash slice
  @tmp{@{$cmp{$compare}}} = undef ;
  INNER:
  foreach my $hash_key ( @hash_keys ) {
    if( exists $tmp{$hash_key} ) {
      printf "Key '%s' is part of '%s'.\n" , $hash_key , $compare ;
      last INNER ;
    }
  }
}

这给出了：

Key 'foo' is part of 'cmp0'.