用于使用邮件应用程序创建新消息的 Applescript

Question

我有一个用于 Mail.app 的 AppleScript，它会打开一个带有预定义收件人地址和主题的新消息窗口。该脚本每次运行时都会打开一个新窗口：

tell application "Mail"
    set newMessage to make new outgoing message with properties {subject:"some subject", content:"" & return & return}
    tell newMessage
        set visible to true
        make new to recipient at end of to recipients with properties {name:"some name", address:"some address"}
    end tell
    activate
end tell

但我希望脚本仅在之前打开的窗口关闭时打开一个新的消息窗口——否则，之前打开的窗口应该出现在前面。

谁能帮我修改这个脚本以实现上述功能？

Answer 1

我没有对此进行测试，但它应该可以满足您的需求……至少它向您展示了正确的方法。您基本上使用“属性”来跟踪上次运行脚本时的某些值。在这种情况下，我们检查最前面窗口的名称，看看它是否符合您的条件。如果窗口名称不能满足您的需要，那么只需在脚本启动之间找到一些其他值来跟踪。基本方法应该有效。

编辑：使用唯一的消息 ID，以下将执行您想要的操作：

property lastWindowID : missing value
tell application "Mail"
    set windowIDs to id of windows
    if windowIDs does not contain lastWindowID then
        set newMessage to make new outgoing message with properties {subject:"some subject", content:"" & return & return}
        tell newMessage
            set visible to true
            make new to recipient at end of to recipients with properties {name:"some name", address:"some address"}
        end tell
        activate
        set lastWindowID to id of window 1
    else
        tell window id lastWindowID
            set visible to false
            set visible to true
        end tell
        activate
    end if
end tell

可见性切换似乎是使窗口位于前面的唯一方法，因为frontmost 是一个只读属性。只要脚本没有重新编译，lastWindowID 属性就会存储 ID（caveat empteor：不要将其放入 Automator 服务，因为它们会重新编译每次加载服务时）。