编写轮询 Windows 服务

Question

我通常使用 C# 编写 Windows 服务，但我尝试使用 F#。对于像这样的轮询服务，我通常使用自己编写的类，类似于BackgroundWorker。它产生一个后台线程并定期触发一个 OnWork 方法。 （完整代码为here ^[github]。）

在 F# 中是否有另一种可能更好或更惯用的方法来做到这一点？这可能是编写轮询后台工作者类或内置替代方案的更好方法。

编辑

这是我根据 Joel 的建议提出的。

module Async =
  open System.Diagnostics

  let poll interval work =
    let sw = Stopwatch()
    let rec loop() =
      async {
        sw.Restart()
        work()
        sw.Stop()
        let elapsed = int sw.ElapsedMilliseconds
        if elapsed < interval then
          do! Async.Sleep(interval - elapsed)
        return! loop()
      }
    loop()

//Example
open System.Threading
let cts = new CancellationTokenSource()
Async.Start(Async.poll 2000 (fun () -> printfn "%A" DateTime.Now), cts.Token)
Thread.Sleep(TimeSpan.FromSeconds(10.0))
cts.Cancel()

服务使用poll:

type MyService() =
  inherit System.ServiceProcess.ServiceBase()

  let mutable cts = new CancellationTokenSource()
  let interval = 2000

  override __.OnStart(_) = 
    let polling = Async.poll interval (fun () ->
      //do work
    )
    Async.Start(polling, cts.Token)

  override __.OnStop() = 
    cts.Cancel()
    cts.Dispose()
    cts <- new CancellationTokenSource()

  override __.Dispose(disposing) =
    if disposing then cts.Dispose()
    base.Dispose(true)

我希望有一种方法可以避免可变的CancellationTokenSource，但是唉。

Answer 1

我可能很想在异步工作流中编写一个简单的循环。您可以使用do! Async.Sleep interval 在轮询之间休眠 - 这有两个优点：您不会为了让线程与Thread.Sleep 闲置而占用线程，如果您通过，do! 会自动为您检查取消将CancellationToken 转换为Async.Start。

另外，如果您的轮询操作涉及网络通信，那么您已经处于异步工作流程中，因此进行异步网络调用变得微不足道。