如果两个模式之间存在字符串，则 bash-delete

Question

我一直在尝试使用sed 来完成以下任务。假设我有以下文件（注意：我的实际文件比这更复杂）：

hello world
foo bar
people people
target
something
done

我想检查两个模式之间是否存在target，在本例中，在foo bar 和done 行之间（包括这两行），如果target 确实存在，则删除整个模式。

我知道如何使用这个sed 命令删除两个模式之间的线：

sed '/people.*/,/done/d' file

但我只想在两个字符串匹配之间存在字符串target 时删除它。

我的逻辑是这样的：

sed -n '/people.*/,/done/p' file | check if target string exists | delete entire pattern found by sed

编辑

我忘了提到在同一行中target 之前和target 之后可以有任意数量的单词。

Answer 1

Sed

如果在其中找到$pattern，这将从$start 删除到$end：

sed ":a;N;\$!ba; s/$start.*$pattern.*$end//g"

这里有两个步骤（语句）：

1. 将整个文件作为单个字符串读取（根据文件大小可能会很糟糕）。如需很好的解释，请参阅https://stackoverflow.com/a/1252191。唯一的区别是 $!ba 之前的额外反引号，以使其与双引号一起使用，这对于在 sed 行内传递 Bash 变量很有用。
2. 常规的旧搜索/替换。

Perl

要处理不贪婪的匹配，如果允许 Perl，请使用：

perl -0777 -p -e 's/$start.*?$pattern.*?$end//s'

这也会将整个文件作为字符串读取。最后的 /s 告诉它包含换行符作为正则表达式匹配的一部分。使用 .* 代替 .*?回到贪婪搜索。

Answer 2

sed 是在单行上进行简单替换的出色工具，但在 1970 年代中期，当 awk 被发明时，它所有用于处理多行的构造都已过时，因此只需使用 awk 来简化、清晰、稳健等。例如使用 GNU awk 进行多字符 RS：

$ awk -v RS='^$' '{sub(/\nfoo bar\n.*target.*\ndone\n/,""); print}' file
hello world

Answer 3

如果文件多次包含done，则无需先将整个文件读入内存并引发贪婪匹配问题的方法是

sed '/^people/ { :loop; N; /\ndone/ ! b loop; /target/ d }' filename

在 Mac OS X 上，显然需要在右括号之前有一个换行符，因此您可以将代码放入多行字符串文字中：

sed '/^people/ { :loop; N; /\ndone/ ! b loop; /target/ d 
}' filename

或者将这个（无论如何更易读）版本的代码放在一个文件中，比如foo.sed，然后使用sed -f foo.sed filename：

/^people/ {
  :loop
  N
  /\ndone/ ! b loop
  /target/ d
}

代码工作如下：

/^people/ {

在以“人”开头的行中

  :loop
  N
  /\ndone/ ! b loop

在循环中获取更多行，直到一个以done 开头（这将是\ndone 第一次出现在模式空间中）

  /target/ d

如果其中有target，请丢弃整个内容

}

否则照常进行（这意味着打印模式空间，因为我们没有将-n 传递给 sed）。

稳健性的一个可能改进是

sed '/^people/ { :loop; N; /\ndone$/! { $! b loop }; /target/ d }' filename

或

/^people/ {
  :loop
  N
  /\ndone/ ! {
    $ ! b loop
  }
  /target/ d
}

更改为/\ndone$/! { $! b loop }。即使没有遇到done，这也会在文件的最后一行结束循环，这会导致文件末尾未完成的people部分不会被丢弃（除非它们包含target）。

Answer 4

迟到的答复

sed '/^foo bar *$/,/^done *$/{/^done *$/!{H;d};/^done *$/{H;g;s/.*//g;x;/.*target.*/d;s/^.//g}}'

找到/^foo bar *$/,/^done *$/之间的所有行

/foo bar/,/done/

这个/^done *$/!{H;d} 从 foo bar 中取出所有行，但不是最后一行“完成”，并将其放在保持空间中。然后从模式空间中删除这些行。

这个/^done *$/{H;g;s/.*//g;x; 取最后一行“完成”并将其附加到保留空间。现在我们有了从 foo bar 行到在保持空间中完成的行的所有行。之后，我们清除模式空间中的所有内容，并将保持空间中的行范围与模式空间中的空行交换（这是为了在瞄准“之间的另一个行范围时始终保持保持空间为空” foo bar”和“完成”。

终于

/.*target.*/d 

我们测试“目标”是否在多模式空间中。如果是，“foo bar”和“done”之间的行范围将被删除

这样可以避免将整个文件作为单个字符串读取

示例

hello world
foo bar
people people
target
something
done
foo bar
.....
.....
.....
done
foo bar
people people
test
something
done

结果

hello world
foo bar
.....
.....
.....
done
foo bar
people people
test
something
done

注意：从 "foo bar" 到 "done" 的行范围内包含 "target" 的行正在被删除