如何在另一个 If Then 语句中使用 Find 和 FindNext？

Question

我正在尝试：

1. 根据字符串“Foot Strike”查找名为 LeftTD 的变量（这部分代码有效，感谢上一个问题的帮助！）
2. 在列表中找到下一个 LeftTD 并将其命名为 LeftTDx
3. 读取/消息框 LeftTD 和 LeftTDx 值
4. 再次执行此操作，直到 H 列为空

输入数据如下所示： Excel Data

所以我希望第一个消息框告诉我，“步骤从第 9 行开始，在第 29 行结束”。我想告诉我的第二个消息框，“步骤从第 29 行开始，在第 34 行结束”。

代码按原样运行，因为它只执行第 1 步和第 4 步（见上文），并且我将其他所有内容都注释掉了：

Private Sub CommandButton1_Click()

Dim ws As Worksheet: Set ws = ThisWorkbook.Sheets("Sheet1")
Dim LeftStrike As Range, FrameLTD As Range, LeftStrike2 As Range 
Dim lrL As Long

lrL = ws.Range("H" & ws.Rows.Count).End(xlUp).Row
'COMMENT: set LeftTD= to something?
Set LeftStrike = ws.Range("H2:H" & lrL) 'COMMENT: .Find(LeftTD)


For Each FrameLTD In LeftStrike
   If InStr(FrameLTD, "Foot Strike") Then
           LeftTD = FrameLTD.Offset(0, 1)
           'COMMENT: LeftTDx = LeftTD.FindNext or is it too easy to ask VBA for : LeftTDx = LeftTD +1
           'COMMENT:StepEnd = LeftTDx.value 
     
    MsgBox "Step starts in row " & LeftTD & " and ends before row " 'COMMENT:& StepEnd
    
    End If
Next FrameLTD
 
End Sub

所以我想我的问题是，如何在我已经建立的查找字符串的 If Then 语句中设置 Find 和 Find Next 代码？

Answer 1

不确定这是否是您想要的，但我认为它看起来很像。请试一试。

Private Sub CommandButton1_Click()

    Dim Ws          As Worksheet
    Dim TdStart     As Long             ' start of range
    Dim Rl          As Long             ' last row
    Dim R           As Long             ' row counter

    Set Ws = ThisWorkbook.Sheets("Sheet1")
    With Ws
        Rl = .Range("H" & .Rows.Count).End(xlUp).Row

        TdStart = 2                          ' start searching in row 2
        For R = (TdStart + 1) To Rl
            ' "Foot Strike" can be anywhere in the cell's text
            '   this test is case sensitive
            If InStr(.Cells(R, "H").Value, "Foot Strike") Or R = Rl Then
                MsgBox "Step starts in row " & TdStart & _
                       " and ends in row " & (R - IIf(R = Rl, 0, 1))
                TdStart = R
            End If
        Next R
    End With
End Sub

顺便说一句，除非您以后想再次使用Ws，否则您无需声明它。相反，您可以直接使用With ThisWorkbook.Sheets("Sheet1")