拆分字符串并分配给 vb.net 中的类对象

Question

我正在尝试拆分字符串，将值分配给类对象。

我的字符串如下所示：

1-|@$@|-TEST1-|@$@|-Yes|||2-|@$@|-TEST2-|@$@|-No|||3-|@$@|-TEST3-|@$@|-Yes|||

我想用分隔符将上面的每个字符串拆分为-|@$@|- 并将其分配给我的类对象。我的类如下所示：

Public Class Employee
   Public Property EmpId As Integer
   Public Property Name as String
   Public Property Value as Boolean
End Class

所以我想将拆分后的字符串中的每个值分配给上述类的对象。

所以应该是这样的：

EmpId = 1
Name = TEST1
Value = True(Or yes Or 1)

我想循环它并将所有 3 个 Emps(TEST1, TEST2, TEST3) 分配给一个列表或单个 Emp 对象。

我正在尝试拆分如下：

Dim myString As String = "1-|@$@|-TEST1-|@$@|-Yes|||2-|@$@|-TEST2-|@$@|-No|||3-|@$@|-TEST3-|@$@|-Yes|||"
Dim delimiter As Char = "-|@$@|-"

Dim subStrings() As String = myString.Split(delimiter)
For Each substring In subStrings
        //assign here
Next

但我无法按预期拆分它。

有什么帮助吗？我可以修改分隔符和对字符串进行必要的更改，使其变得简单高效。

提前致谢。

Answer 1

您需要将分隔符声明为数组。你真的应该将它声明为一个字符串数组，以利用正确的重载。

Dim delimiter As String= New String() {"-|@$@|-"}

目前正在发生的事情是将分隔符的值设置为“-”，这是分配它的字符串的第一个字符。这导致您拆分破折号而不是您预期的子字符串。

您可以使用以下 LINQ 表达式完全填充您的员工集合：

Dim employees = 
    From employeeRows In myString.Split(New String() {"|||"}, StringSplitOptions.None)
    Let employeeValues = employeeRows.Split(New String() {"-|@$@|-"}, StringSplitOptions.None)
    Where Not employeeValues.Any(Function(x) String.IsNullOrWhiteSpace(x))
    Select New Employee With{
            .EmpId = Integer.Parse(employeeValues(0)),
            .Name = employeeValues(1),
            .Value = If(employeeValues(2) = "Yes", True, False)
            }

Answer 2

尝试使用正则表达式，按照下一个示例：

        Dim myString As String = "1-|@$@|-TEST1-|@$@|-Yes|||2-|@$@|-TEST2-|@$@|-No|||3-|@$@|-TEST3-|@$@|-Yes|||"


        Dim objects = Text.RegularExpressions.Regex.Split(myString, "\|\|\|", Text.RegularExpressions.RegexOptions.IgnoreCase)
        Dim lst As List(Of Employee) = New List(Of Employee)

        For Each k In objects
            If k.Trim <> "" Then
                Dim props = Text.RegularExpressions.Regex.Split(k, "-\|\@\$\@\|-", Text.RegularExpressions.RegexOptions.IgnoreCase)
                lst.Add(New Employee() With {.EmpId = props(0), .Name = props(1), .Value = If(props(2) = "Yes", True, False)})
            End If
        Next

        Console.WriteLine("{0,10} {1,10} {2,10}", "Id", "Value", "Name")

        lst.ForEach(New Action(Of Employee)(Sub(t)
                                                Console.WriteLine("{0,10} {1,10} {2,10}", t.EmpId, t.Value, t.Name)
                                            End Sub))

        Console.ReadLine()

如果你看到了，我使用了两个拆分，第一个用于“|||”然后是“-|@$@|-”。 我在控制台应用程序上运行此代码并且工作正常。