TypeError：错误＃1006：值不是函数-我做错了什么？

Question

首先，通过搜索，我意识到这个问题已经被问过一千次了，很抱歉，但我在解释答案时遇到了麻烦。我是 ActionScript 3 的新手，一般来说只是一个新手程序员。

所以我正在编写一个简单的游戏，其中一些球会移动并加速。但是，每当我调用我的碰撞检查函数 (isWithin) 时，它都会给出错误 #1006：值不是函数。我是否错误地调用或声明了函数？

import flash.ui.Keyboard;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.text.TextField;
import flash.text.TextFormat;

// add the event listeners
PlayerBall.addEventListener(Event.ENTER_FRAME, update);
stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);

// this array holds references to all the keys

var keys:Array = [];

var xSpeed1:Number = 0;
var ySpeed1:Number = 0;

var xSpeed2:Number = 0;
var ySpeed2:Number = 0;

var hasFlag:int = 0;

var collide:Boolean = false;

function isWithin(object1:Object, object2:Object, barrier:Number):Boolean
{
var distance:Number = Math.sqrt((object1.x - object2.x)(object1.x - object2.x) + (object1.y - object2.y)(object1.y - object2.y));

if(distance <= barrier)
{
    return(true);
}
else
{
    return(false);
}
}

collide = isWithin(PlayerBall, PlayerBall2, PlayerBall.width);
trace(collide);

function update(e:Event):void
{

// GETTING KEYBOARD INPUT FOR FRAME
if(keys[Keyboard.UP])
{
    ySpeed1 = ySpeed1 < -5 ? ySpeed1 : ySpeed1 - .3;
}
if(keys[Keyboard.DOWN])
{
    ySpeed1 = ySpeed1 > 5 ? ySpeed1 : ySpeed1 + .3;
}
if(!(keys[Keyboard.UP]) && !(keys[Keyboard.DOWN]))
{
    ySpeed1 = ySpeed1 > 0 ? ySpeed1 - .2 : ySpeed1 + .2;
}


if(keys[Keyboard.RIGHT])
{
    xSpeed1 = xSpeed1 > 5 ? xSpeed1 : xSpeed1 + .3;
}
if(keys[Keyboard.LEFT])
{
    xSpeed1 = xSpeed1 < -5 ? xSpeed1 : xSpeed1 - .3;
}
if(!(keys[Keyboard.RIGHT]) && !(keys[Keyboard.LEFT]))
{
    xSpeed1 = xSpeed1 > 0 ? xSpeed1 - .2 : xSpeed1 + .2;
}

if(keys[Keyboard.W])
{
    ySpeed2 = ySpeed2 < -5 ? ySpeed2 : ySpeed2 - .3;
}
if(keys[Keyboard.S])
{
    ySpeed2 = ySpeed2 > 5 ? ySpeed2 : ySpeed2 + .3;
}
if(!(keys[Keyboard.W]) && !(keys[Keyboard.S]))
{
    ySpeed2 = ySpeed2 > 0 ? ySpeed2 - .2 : ySpeed2 + .2;
}


if(keys[Keyboard.D])
{
    xSpeed2 = xSpeed2 > 5 ? xSpeed2 : xSpeed2 + .3;
}
if(keys[Keyboard.A])
{
    xSpeed2 = xSpeed2 < -5 ? xSpeed2 : xSpeed2 - .3;
}
if(!(keys[Keyboard.A]) && !(keys[Keyboard.D]))
{
    xSpeed2 = xSpeed2 > 0 ? xSpeed2 - .2 : xSpeed2 + .2;
}

// MOVEMENT

PlayerBall.x += xSpeed1;
PlayerBall.y += ySpeed1;

PlayerBall2.x += xSpeed2;
PlayerBall2.y += ySpeed2;

if(hasFlag == 1)
{
    flag.x = PlayerBall.x;
    flag.y = PlayerBall.y;
}
if(hasFlag == 2)
{
    flag.x = PlayerBall2.x;
    flag.y = PlayerBall2.y
}

// COLLISION CHECKING

collide = isWithin(PlayerBall, flag, PlayerBall.width/2 + flag.width/2);

if(flag.visible && collide)
{
    hasFlag = 1;
    flag.visible = false;

    flag.x = PlayerBall.x;
    flag.y = PlayerBall.y;
}

collide = isWithin(PlayerBall2, flag, (PlayerBall2.width/2 + flag.width/2));

if(flag.visible && collide)
{
    hasFlag = 2;
    flag.visible = false;

    flag.x = PlayerBall2.x;
    flag.y = PlayerBall2.y;
}
}

function onKeyDown(e:KeyboardEvent):void
{
    keys[e.keyCode] = true;
}

function onKeyUp(e:KeyboardEvent):void
{
keys[e.keyCode] = false;
}

Answer 1

好吧，我可以看到您的“var distance”计算存在问题。如果您的意思是将括号中的减法值相乘，则应在每对的结束括号和开始括号之间放置一个“*”，即：

var distance:Number = Math.sqrt((object1.x - object2.x)*(object1.x - object2.x) + (object1.y - object2.y)*(object1.y - object2.y));

我猜你得到了那个特定的错误，因为编译器将每对括号中的第二组括号解释为包含函数的参数。因此“价值不是函数”。

Answer 2

您缺少乘法运算符。请换行

var distance:Number = Math.sqrt((object1.x - object2.x)(object1.x - object2.x) + (object1.y - object2.y)(object1.y - object2.y));

到

var distance:Number = Math.sqrt((object1.x - object2.x)*(object1.x - object2.x) + (object1.y - object2.y)*(object1.y - object2.y));