当结果可能为空时，如何在 PL/SQL 中选择变量？

Question

有没有办法只运行一次查询以选择变量，考虑到查询可能不返回任何内容，那么在这种情况下，变量应该为空。

目前，我不能直接执行select into 变量，因为如果查询不返回任何内容，PL/SQL 会抱怨变量未设置。我只能运行两次查询，第一次进行计数，如果计数为零，则将变量设置为 null，如果计数为 1，则选择变量。

所以代码是这样的：

v_column my_table.column%TYPE;
v_counter number;
select count(column) into v_counter from my_table where ...;
if (v_counter = 0) then
    v_column := null;
elsif (v_counter = 1) then
    select column into v_column from my_table where ...;
end if;

谢谢。

更新： 我没有使用异常的原因是我在分配了v_column之后仍然有一些以下逻辑，我必须在异常部分使用goto才能跳转回下面的代码。我有点犹豫goto 行。

Answer 1

COALESCE 将始终返回第一个非空结果。通过这样做，您将获得所需的计数或 0：

select coalesce(count(column) ,0) into v_counter from my_table where ...;

Answer 2

从上面的所有答案中，Björn's answer 似乎是最优雅和最简短的。我个人多次使用这种方法。 MAX 或 MIN 函数同样可以很好地完成这项工作。下面是完整的 PL/SQL，只需指定 where 子句。

declare v_column my_table.column%TYPE;
begin
    select MIN(column) into v_column from my_table where ...;
    DBMS_OUTPUT.PUT_LINE('v_column=' || v_column);
end;

Answer 3

我知道这是一个旧线程，但我仍然认为值得回答。

select (
        SELECT COLUMN FROM MY_TABLE WHERE ....
        ) into v_column
from dual;

使用示例：

declare v_column VARCHAR2(100);
begin
  select (SELECT TABLE_NAME FROM ALL_TABLES WHERE TABLE_NAME = 'DOES NOT EXIST')
  into v_column 
  from dual;
  DBMS_OUTPUT.PUT_LINE('v_column=' || v_column);
end;

Answer 4

使用 MAX 怎么样？ 这样，如果没有找到数据，则将变量设置为 NULL，否则设置为最大值。
由于您期望值为 0 或 1，因此 MAX 应该可以使用。

v_column my_table.column%TYPE;
select MAX(column) into v_column from my_table where ...;

Answer 5

使用Cursor FOR LOOP Statement 是我最喜欢的方式。

它比使用显式游标更安全，因为您不需要记住关闭它，因此您不能“泄漏”游标。

您不需要“进入”变量，不需要“获取”，也不需要捕获和处理“未找到数据”异常。

试试吧，你永远不会回去。

v_column my_table.column%TYPE;

v_column := null;

FOR rMyTable IN (SELECT COLUMN FROM MY_TABLE WHERE ....) LOOP
  v_column := rMyTable.COLUMN;
  EXIT;  -- Exit the loop if you only want the first result.
END LOOP;

Answer 6

我使用这种语法是为了灵活性和速度-

    begin
    --
    with KLUJ as
    ( select 0 ROES from dual
       union 
      select count(*) from MY_TABLE where rownum = 1
    ) select max(ROES) into has_rows from KLUJ;
    --
    end;

Dual 返回 1 行，rownum 添加 0 或 1 行，而 max() 组正好为 1。这为表中没有行提供 0，为任何其他行数提供 1。

我将 where 子句扩展为按条件计算行数，删除 rownum 以计算满足条件的行数，并增加 rownum 以计算满足条件的行数达到限制。

Answer 7

我建议使用游标。游标提取始终是单行（除非您使用批量集合），并且游标不会自动抛出 no_data_found 或 too_many_rows 异常；虽然您可以在打开后检查游标属性以确定您是否有一行以及有多少。

declare
v_column my_table.column%type;
l_count pls_integer;
cursor my_cursor is
  select count(*) from my_table where ...;

begin
  open my_cursor;
    fetch my_cursor into l_count;
  close my_cursor;

  if l_count = 1 then
    select whse_code into v_column from my_table where ...;
  else
    v_column := null;
  end if;
end;

或者，更简单：

    declare
    v_column my_table.column%type;
    cursor my_cursor is
      select column from my_table where ...;

    begin
      open my_cursor;
        fetch my_cursor into v_column;
        -- Optional IF .. THEN based on FOUND or NOTFOUND
        -- Not really needed if v_column is not set
        if my_cursor%notfound then
          v_column := null;
        end if;
      close my_cursor;
    end;

Answer 8

您可以通过将变量设置为NULL 来简单地处理NO_DATA_FOUND 异常。这样，只需要一个查询。

    v_column my_table.column%TYPE;

BEGIN

    BEGIN
      select column into v_column from my_table where ...;
    EXCEPTION
      WHEN NO_DATA_FOUND THEN
        v_column := NULL;
    END;

    ... use v_column here
END;