Gnuplot：使用统计输出作为数据点

Question

我有三个数据文件，每个文件都有一个矩阵；我使用 stats 来查找每个文件的矩阵中的最大值并正确显示。我需要使用这三个最大值作为数据点并绘制它们，以便在我的图上有点为 (1.0, A_max), (2.0, B_max) 和 (3.0, C_max) 其中 A_max 是使用统计数据计算的最大值第一个数据文件，B_max 来自第二个，C_max 来自第三个。这是我的 gp 文件的样子：

    set terminal epslatex size 3.5,2.62 color colortext
    set output 'data.tex'
    set xlabel '$x$'
    set ylabel '$y$'

    stats 'dataA.txt' matrix name "A"
    show variables A_
    stats 'dataB.txt' matrix name "B"
    show variables B_
    stats 'dataC.txt' matrix name "C"
    show variables C_

    plot '-' w p, '-' w p, '-' w p
    1.0 A_max
    e   
    2.0 B_max
    e
    3.0 C_max
    e

我得到的情节如下所示。

显然，它将 x 轴设为 0，而我打算为 x 轴设置的点对应于 y。不知道我错过了什么，可能是如何读取 stats 变量。任何帮助将不胜感激。

Answer 1

与您使用的一样，内联数据按原样使用，无需任何变量替换。 使用set print $data将数据打印到命名数据块$data：

set print $data
stats 'dataA.txt' matrix name "A"
print sprintf("%e A", A_max)
stats 'dataB.txt' matrix name "B"
print sprintf("%e B", B_max)
stats 'dataC.txt' matrix name "C"
print sprintf("%e C", C_max)
plot $data using 0:1:xticlabel(2) w p notitle

或者，自动化程度更高：

set print $data
do for [f in "A B C"]{
    stats 'data'.f.'.txt' matrix name f
    print sprintf("%e %s", value(f.'_max), f)
}
plot $data using 0:1:xticlabel(2) w p notitle