获取范围内的特定项目

Question

这是我的代码：

    Debug.Print "Full range: " & searchResult.Address
    Debug.Print "Size of range: " & searchResult.Count
    Dim cell As Range
    For Each cell In searchResult
        Debug.Print "from for each: " & cell.Address
    Next cell
    Debug.Print "from item 0: " & searchResult.item(0).Address
    Debug.Print "from item 1: " & searchResult.item(1).Address
    Debug.Print "from item 2: " & searchResult.item(2).Address

这是我的输出：

Full range: $M$125,$M$148,$M$161
Size of range: 3
from for each: $M$125
from for each: $M$148
from for each: $M$161
from item 0: $M$124
from item 1: $M$125
from item 2: $M$126

for each 给了我想要的结果，而“item”只给出了工作表中的下一个项目，而不是那个范围。 我只想获取该范围内特定项目的地址。假设像“searchResult(2).address = $M$161”（如果它是基于 0 的情况下）之类的话，就像您将访问数组中的项目一样。 我确定这很简单，但找不到我需要使用的属性的名称... 感谢您的帮助。

Answer 1

不连续的范围不会返回连续的数组...

为了将其转换为一维数组（值和地址），请尝试下一个函数。它在所有范围区域和每个区域的所有单元格之间进行迭代：

Function DiscRangeToArray(rng As Range) As Variant
   Dim A As Range, c As Range, arrVal, arrAddress, i As Long
   ReDim arrVal(rng.cells.count - 1): ReDim arrAddress(rng.cells.count - 1)
   For Each A In rng.Areas
        For Each c In A.cells
            arrVal(i) = c.value: arrAddress(i) = c.Address: i = i + 1
        Next c
    Next A
    DiscRangeToArray = Array(arrVal, arrAddress)
End Function

你可以使用下一个测试Sub来测试它：

Sub testDiscRangeToArray()
   Dim rng As Range, jgArr
   Set rng = Range("$M$125,$M$148,$M$161")
   jgArr = DiscRangeToArray(rng)
   Debug.Print Join(jgArr(0), "|")
   Debug.Print Join(jgArr(1), "|")
   
   'For a range not having only one cell in an area:
   Set rng = Range("A2:A3,B4,C5:D6")
   jgArr = DiscRangeToArray(rng)
   Debug.Print Join(jgArr(0), "|")
   Debug.Print Join(jgArr(1), "|")
End Sub

请进行测试并发送一些反馈。

Answer 2

感谢 FaneDuru 的评论，我找到了解决方案。正在做：

searchResult.Areas.item(1).Address

在我的情况下完成了这项工作。