循环重复代码以设置用户表单复选框值

Question

我有一个仪表板，它使用带有复选框的用户表单框字段来选择要在图表上显示的数据。

我的代码非常复制粘贴。

Private Sub CommandButton21_Click()
UserForm1.Show
If Worksheets("Data Directorate").Range("X4").Value = True Then UserForm1.CheckBox1 = True
If Worksheets("Data Directorate").Range("X5").Value = True Then UserForm1.CheckBox2 = True
If Worksheets("Data Directorate").Range("X6").Value = True Then UserForm1.CheckBox3 = True

有没有办法使用循环来做到这一点？

我后面有更多重复的代码：

Private Sub CheckBox1_Click()
  Select Case CheckBox1.Value
  Case True
  Worksheets("Data Directorate").Range("X4").Value = True
  Case False
  Worksheets("Data Directorate").Range("X4").Value = False
End Select
End Sub

这会重复 24 个复选框。可以循环播放吗？

Answer 1

在这个帖子中发布了所有很棒的建议，所以我想添加一些可能有助于简化循环的内容。控件有一个Tag 属性，据我所知，它除了存储有关控件的附加信息外什么也不做。

利用这一点，我们可以在每个复选框的Tag 属性中包含链接单元格。 （例如，在Tag 中输入X4 以链接到单元格X4）。这允许更少的信息被硬编码，从而使其更具适应性。

最后，代码将如下所示。

Private Sub UserForm_Click()
    For Each octrl In Me.Controls
        If TypeName(octrl) = "CheckBox" Then
            Sheet1.Range(octrl.Tag).Value = octrl.Value
        End If

    Next octrl
End Sub

Answer 2

我在这种情况下的方法是：

将复选框的ControlSource 属性设置为适当的单元格，仅保留： UserForm1.Show

Answer 3

要简化的一件事：不要使用 If 语句，只需使两侧相等即可。像这样：

Private Sub CommandButton21_Click()
UserForm1.Show

UserForm1.CheckBox1 = Worksheets("Data Directorate").Range("X4").Value

还有一个：

Private Sub CheckBox1_Click()
  Worksheets("Data Directorate").Range("X4").Value = CheckBox1.Value
End Sub

我建议使用更改事件而不是点击事件。有些用户可能会使用Tab 和Space，则不会触发点击事件。像这样：

Private Sub CheckBox1_Change()
...

关于遍历 CommandButton21_Click 事件中的复选框，这取决于复选框和表格的顺序。这可能有效，但你必须在你的桌子上尝试它（复选框的顺序与单元格的顺序相比可能会破坏游戏......）

Dim contr As control
dim i as integer
i=4
For Each contr In UserForm1.Controls
  If TypeName(contr) = "CheckBox" Then
    contr.Value = cells(i,24).Value 'column 24 is column X
    i=i+1
  End If
Next

当 CheckBox 未按预期顺序或被添加/删除时可能会发生变化：

Dim contr As control
Dim J as Integer
Dim Offset as Integer

Offset = 3  'set this to the difference between 1 and the first row containing data

For Each contr In UserForm1.Controls
  If TypeName(contr) = "CheckBox" Then
    'set j to the checkboxes "number"
    J = cInt(right(contr.name, len(contr.name) - len("CheckBox")))
    'use the checkbox number + offset to find the row we want
    contr.Value = cells(J + Offset,24).Value 'column 24 is column X
  End If
Next

希望这会有所帮助。

Answer 4

关于你问题的第二部分：

Private Sub CheckBox1_Click()
  Worksheets("Data Directorate").Range("X4").Value = CheckBox1.Value
End Sub

Answer 5

您可以在给定框架内对复选框进行分组并尝试以下操作

Sub Test()
    Dim i As Long
    i = 5
    For Each cb In UserForm1.Frame1.Controls
        If Worksheets("Data Directorate").Range("X" & i).Value = True Then cb.Value = True
        i = i + 1
    Next cb
End Sub