在 Perl 中，如何使用 `s///` 进行多次替换？

Question

我的意见：

 $brackets = '\left \right \center \right \left \middle';

在上面的字符串中，我需要将每个\left 字符串替换为( 左大括号，并将每个\right 字符串替换为) 右大括号。

我可以用几种方法替换来获得输出。但是我想知道我们如何在r 修饰符中做到这一点。这是我目前所拥有的

 $brackets=~s{\\(left|right)}{$&=~s/\\left/\(/r && $&=~s/\\right/\)/gr; }ge;

我不知道我在哪里可以找到我的错误。

Answer 1

对于这个只涉及要替换的两个子字符串的字面问题，您应该使用两个单独的s/// 作为@Patrick85 recommends。只有当您有 3 个或更多这样的替换时，下面的方法才开始有意义。在这种情况下，将映射隐藏在散列中将使您的代码更清晰。

使用哈希查找替换：

#!/usr/bin/env perl

use strict;
use warnings;

my %replacement = (
    '\left' => '(',
    '\right' => ')'
);

my $s = '\left \right \center \right \left \middle';
my $t = $s =~ s/( \\ (?: left | right ))/$replacement{$1}/rgx;

print "$s\n$t\n";

试图将所有内容都塞进一行会有很多问题：

$brackets=~s{\\(left|right)}{$&=~s/\\left/\(/r && $&=~s/\\right/\)/gr; }ge;

很难阅读。此外，无法一概而论。如果您需要将 N 个字符串映射到它们的替换，会发生什么？让我们尝试通过添加一些空格来更清楚地写下这段代码：

$brackets =~ s{
    \\
    (left | right)
}{
    $& =~ s/\\left/\(/r &&
    $& =~ s/\\right/\)/gr; 
}gex;

即使这符合您的要求，您现在也已将单个 s/// 与简单的哈希查找替换为对源字符串中的每个匹配项执行两个额外的 s/// 操作的东西。

对于您显示的示例字符串，这个字符串将执行 八 个额外的 s/// 操作。

这样不好。

Answer 2

使用两个简单的替换而不是一个复杂的替换：

#!/usr/bin/env perl
use strict;
use warnings;

my $brackets = '\left \right \center \right \left \middle';

$brackets =~ s/\\left/(/g;
$brackets =~ s/\\right/)/g;

print $brackets."\n";

输出：

( ) \center ) ( \middle

Answer 3

建立一个替换列表相当容易。

use strict;
use warnings;

my $brackets = '\left \right \center \right \left \middle';

for ( $brackets ) {
    s/\\left/(/g;
    s/\\right/)/g;
}

print $brackets, "\n";

显然你仍然可以添加到列表中并删除空格。

More information about this method:

Answer 4

只是我需要关闭这个我的问题。 @Wiktor Stribiżew [in Comment] 就我的问题提供了答案。

$brackets = '\left \right \center \right \left \middle';

我的要求：

$brackets=~s{\\(left|right)}{$&=~s/\\left/\(/r && $&=~s/\\right/\)/gr; }ge;

答案：

$brackets=~s/\\((left)|right)/$2 ? '(' : ')'/eg;