'With Worksheets("xxxx")' 仅在 "xxxx" 是活动工作表时有效

Question

我对 Excel VBA 还是很陌生。到目前为止，我在这个网站上阅读并学到了很多东西，但还没有找到解决我的问题的方法。

作为宏的一部分，我有以下代码：

With Worksheets("Oracle")
    On error resume next
    ActiveWorkbook.Names("bron").Delete
    ActiveWorkbook.Names.Add Name:="bron", RefersTo:= Range("A1", Range("A1").End(xlToRight).End(xlDown))
    .Cells.Select
    With Selection.Font
        .Name = "Verdana"
        .FontStyle = "Standaard"
        .Size = 8
    End With
    .Range("A1", Range("A1").End(xlToRight)).Font.Bold = True
    MsgBox "Tabblad ‘Oracle’ is klaar!", vbOKOnly
End With

我知道，对于代码的第一行，活动工作表实际上是什么并不重要。但问题是它仅在 Oracle 是活动工作表时才有效。我做错了什么？

Answer 1

如果您使用With Worksheets() ... End With，则意味着您要引用特定工作表而不是ActiveSheet。这在 VBA 中被认为是一种很好的做法。

正如@GSerg 在 cmets 中所提到的，您的代码不起作用，因为您在所有范围前面都没有一个点。但是，您不会注意到这一点，因为您使用的是On Error Resume Next，它会忽略所有错误。

在您的情况下，问题是您尝试使用此行.Range("A1", Range("A1").End(xlToRight)). 引用ActiveSheet 和Oracle 中的范围。因此，错误是不可避免的。

您有两种选择来确保您的代码正常工作：

1. 只需激活工作表“Oracle”并运行代码。它会正常工作的。
2. 尝试像这样重写它：

---

With Worksheets("Oracle")
    On Error Resume Next
    ActiveWorkbook.Names("bron").Delete
    ActiveWorkbook.Names.Add Name:="bron", _
                          RefersTo:=.Range("A1", .Range("A1").End(xlToRight).End(xlDown))

        With .Cells.Font
            .Name = "Verdana"
            .FontStyle = "Standaard"
            .Size = 8
        End With

    .Range("A1", .Range("A1").End(xlToRight)).Font.Bold = True
    MsgBox "Tabblad ‘Oracle’ is klaar!", vbOKOnly

End With

看看所有范围都用一个点引用，Select 命令不再使用。