类型族内的多态函数

Question

我正在尝试在类型族中定义一个函数，该函数在类型族中定义的 GADT 本身的幻像类型上具有多态性。

我的类型族定义大致如下：

class Channel t where
    data Elem t a :: * 
    foo :: t -> Elem t a
    bar :: Elem t a -> [a]

我有一个实例如下：

data MyChannelType = Ch

instance Channel MyChannelType where

    data Elem MyChannelType a where
        MyConstructor :: Char -> Elem MyChannelType Char

    foo _ = MyConstructor 'a'

    bar (MyConstructor c) = repeat c

编译器抱怨：

Couldn't match type ‘a’ with ‘Char’
      ‘a’ is a rigid type variable bound by
          the type signature for foo :: MyChannelType -> Elem MyChannelType a

是否可以使用 Rank2Types 编写此函数或重新格式化我的数据类型以启用它？

---

编辑：响应 Ganesh 要求的澄清

我希望foo (bar Ch) :: [Int] 是非法的。

我一直在完全使用 Ganesh 建议的解决方案，但我受到以下更复杂示例的启发，该示例失败了；给定：

data MyOtherType = IntCh | StringCh

我有一个实例如下：

instance Channel MyOtherType where

    data Elem MyOtherType a where
        ElemInt    :: Int ->    Elem MyOtherType Int
        ElemString :: String -> Elem MyOtherType String

    foo IntCh    = ElemInt 0
    foo StringCh = ElemString "a"

    bar (ElemInt i)    = repeat i
    bar (ElemString s) = repeat s

非常感谢，

迈克尔

Answer 1

根据您给出的签名，foo 对于 MyChannelType 是无法实现的，因为它声称能够为任何 a 类型生成 Elem MyChannelType a。

如果你真正想要的是给定的a 类型应该只有一个t，你可以使用类型函数来表达：

class Channel t where
    data Elem t a :: *
    type Contents t :: *

    foo :: t -> Elem t (Contents t)
    bar :: Elem t a -> [a]

然后添加

type Contents MyChannelType = Char

到实例。

作为对您的编辑的回应，我会将Channel 分成两个类：

class Channel t where
    data Elem t a :: *
    bar :: Elem t a -> [a]

class Channel t => ChannelContents t a where
    foo :: t -> Elem t a

然后您可以使用以下命令定义 MyOtherType 实例：

instance Channel MyOtherType where

    data Elem MyOtherType a where
        ElemInt :: Int -> Elem MyOtherType Int
        ElemString :: String -> Elem MyOtherType String

    bar (ElemInt i) = repeat i
    bar (ElemString s) = repeat s

instance ChannelContents MyOtherType Int where
    foo IntCh = ElemInt 0

instance ChannelContents MyOtherType String where
    foo StringCh = ElemString "a"

您需要启用一些扩展：MultiParamTypeClasses、TypeSynonymInstances、FlexibleInstances（后两个只是因为 String 实例）。

Answer 2

作为 Ganesh 解决方案的更通用替代方案，您还可以将 a 变量限制为一整类类型（可能只是一个类型）：

{-# LANGUAGE ConstraintKinds #-}
import GHC.Exts (Constraint)

class Channel t where
    data Elem t a :: *
    type ElemConstraint t a :: Constraint
    foo :: ElemConstraint t a => t -> Elem t a
    bar :: ElemConstraint t a => Elem t a -> [a]

instance Channel MyChannelType where
    data Elem MyChannelType a where
        MyConstructor :: Char -> Elem MyChannelType Char
    type ElemConstraint t a = a ~ Char
    foo _ = MyConstructor 'a'
    bar (MyConstructor c) = repeat c


class OtherType_Class c where
  mkOtherTypeElem :: c -> Elem MyOtherType c
  evOtherTypeElem :: Elem MyOtherType c -> c

instance OtherType_Class Int where
  mkOtherTypeElem = ElemInt
  evOtherTypeElem (ElemInt i) = i
instance OtherType_Class String where
  ...

instance Channel MyOtherType where
    data Elem MyOtherType a where
        ElemInt    :: Int ->    Elem MyOtherType Int
        ElemString :: String -> Elem MyOtherType String
    type ElemConstraint MyOtherType a = OtherType_Class a

但是，我应该说，对于一些固定的类型集合来说，这是一件相当尴尬的事情。