Haskell 错误：无法推断（随机 a0）源于

Question

我在玩随机函数，它给出了一个无限的随机值列表，如“Learn You a Haskell for Great Good”的第 9 章所示。代码如下：

randoms' :: (RandomGen g, Random a) => g -> [a]
randoms' gen = let (value, newGen) = random gen
               in value : randoms' newGen

为了记录随机生成器，我将randoms' 更改为以下内容：

randoms'' :: (RandomGen g, Random a) => g -> [(a, g)]
randoms'' gen = let (value, newGen) = random gen
                in (value, newGen) : randoms'' newGen

它按预期工作。

然后我用列表理解的方式重写了它：

randoms''' :: (RandomGen g, Random a) => g -> [(a, g)]
randoms''' gen = random gen : [random gen' | (_, gen') <- randoms''' gen]

这一次，编译器给出了错误：Could not deduc (Random a0) generated from a use of 'randoms''''......类型变量'a0'不明确......

但是，如果我使用具体类型指定 randoms''' 的类型，例如，

randoms''' :: StdGen -> [(Int, StdGen)]
randoms''' gen = random gen : [random gen' | (_, gen') <- randoms''' gen]

它再次正常工作，并给出与randoms''完全相同的结果。

我想知道为什么类型推断适用于randoms''，但对于randoms''' 却失败了。谁能告诉我为什么这两个不相等以及如何修复randoms'''的代码？

此外，我尝试了具有类似结构的测试代码：

generate :: (Integral a, RealFrac b) => a -> (b,a)
generate m = let x = 1.2^^m in (x, ceiling x)

foo :: (Integral g, RealFrac a) => g -> [(a,g)]
foo gen = let (value, newGen) = generate gen
          in (value, newGen) : foo newGen

foo' :: (Integral g, RealFrac a) => g -> [(a, g)]
foo' gen = generate gen : [generate gen' | (_, gen') <- foo' gen]

foo'' :: (Integral g, RealFrac a) => g -> [(a, g)]
foo'' gen = [generate gen' | gen' <- gen : map snd (foo'' gen)]

事实证明 foo、foo' 和 foo'' 都可以正常工作。显然，这不是单态与多态的问题。这似乎是 random 特有的问题。

Answer 1

(_, gen') <- randoms''' gen

这里有_ 的类型是什么？您可能认为它应该是randoms''' 的签名中给出的a。然而，这是任意的。可能是()，也可能是Char。一切都可以在这里工作，因为无论如何你都不使用它。我们可以强制它与random gen'具有相同的类型：

randoms''' gen = random gen : [random gen' `asTypeOf` x | x@(_, gen') <- randoms''' gen]

asTypeOf 是一个标准函数，基本上是const 的类型约束版本：

asTypeOf :: a -> a -> a
asTypeOf = const

通过这个函数，我们可以确定x 的类型，从而确定_ 的类型，因为random gen' 的类型是已知的。