Haskell 中的多态返回类型和“刚性类型变量”错误

Question

有一个简单的记录Column v a 包含来自Data.Vector 家族的Vector（因此v 可以是Vector.Unboxed，只是Vector 等），它的名称和类型（类似简单的枚举ADT SupportedTypes)。我希望能够使用binary 包对其进行序列化。为此，我尝试在下面定义一个Binary 实例。

现在put 工作正常，但是当我尝试在get 函数中定义反序列化并希望将特定类型设置为基于colType 返回的rawVector（U.Vector Int64 时它是 PInt、U.Vector Double，当它是 PDouble 等） - 我收到此错误消息：

无法将类型 v 与 U.Vector 匹配

v 是一个刚性类型变量，由src/Quark/Base/Column.hs:75:10 处的实例声明绑定

预期类型：v a

实际类型：U.Vector Int64

错误。

有没有更好的方法来实现我的目标 - 根据 colType 值反序列化不同类型的 Vectors，还是我坚持为所有可能的 Vector / 原始类型组合定义 Binary 实例？不应该这样……

对 Haskell 有点陌生，感谢任何帮助！谢谢！

{-# LANGUAGE OverloadedStrings, TransformListComp, RankNTypes, 
            TypeSynonymInstances, FlexibleInstances, OverloadedLists, DeriveGeneric  #-}

{-# LANGUAGE MultiParamTypeClasses, FlexibleContexts,
         TypeFamilies, ScopedTypeVariables, InstanceSigs #-}

import qualified Data.Vector.Generic as G
import qualified Data.Vector.Unboxed as U

data Column v a = Column {rawVector :: G.Vector v a => v a, colName :: Text, colType :: SupportedTypes }

instance (G.Vector v a, Binary (v a)) => Binary (Column v a) where

  put Column {rawVector = vec, colName = cn, colType = ct} = do put (fromEnum ct) >> put cn >> put vec


  get = do t <- get :: Get Int
         nm <- get :: Get Text
         let pt = toEnum t :: SupportedTypes
         case pt of 
            PInt -> do vec <- get :: Get (U.Vector Int64)
                       return Column {rawVector = vec, colName = nm, colType = pt}
            PDouble -> do vec <- get :: Get (U.Vector Double)
                          return Column {rawVector = vec, colName = nm, colType = pt}

更新感谢您在下面的所有答案，一些非常好的想法！很明显，我想做的事情是不可能正面实现的——这就是我的答案。但是其他建议的解决方案本身就是一个很好的阅读，非常感谢！

Answer 1

你真正想要表示的类型是

data Column v = Column (Either (v Int) (v Double))

但这种表述可能会让您不满意。那么如何在构造函数的“顶层”使用向量本身来编写这种类型呢？

首先，从类型级别而不是值级别的总和 (Either Int Double) 表示开始：

data IsSupportedType a where 
  TInt :: IsSupportedType Int 
  TDouble :: IsSupportedType Double 

从这里Column其实很简单：

data Column v a = Column (IsSupportedType a) (v a) 

但您可能希望a 存在量化，以便按照您的意愿使用它：

data Column v = forall a . Column (IsSupportedType a) (v a) 

二进制实例如下：

instance (Binary (v Int), Binary (v Double)) => Binary (Column v) where
  put (Column t v) = do 
    case t of 
      TInt -> put (0 :: Int) >> put v 
      TDouble -> put (1 :: Int) >> put v 

  get = do 
    t :: Int <- get 
    case t of 
      0 -> Column TInt <$> get  
      1 -> Column TDouble <$> get 

请注意，这里没有对 Vector 的固有依赖 - v 真的可以是任何东西。

Answer 2

您实际遇到的问题（或者如果您还没有遇到，您会遇到的）是您试图从输入值中确定结果类型。你不能这样做。完全没有。您可以巧妙地将结果类型锁定在一个盒子中并扔掉钥匙，这样该类型从外面看起来是正常的，但是您不能对它做任何事情，因为您将类型锁定在一个盒子中并扔掉了键。您可以使用 GADT 存储有关它的额外信息并将其与类型类实例打包，但这仍然不是一个好主意。

如果您只为 Column 提供两个构造函数来反映是否存在 Ints 或 Doubles 的向量，那么您可以在这里轻松得多。

但实际上，不要这样做。只需让可自动派生的 Binary 实例将任何可反序列化的值反序列化到您的向量中即可。

data Column a = ... deriving (Binary)

使用DeriveAnyClass 扩展，您可以派生任何具有Generic 实现（Binary 具有）的类。然后在需要时反序列化 Column Double 或 Column Int。

Answer 3

正如评论所说，您可以简单地不区分类型，并始终调用

vec <- get
return Column {rawVector = vec, colName = nm, colType = pt}

这会正确地满足您的类型签名。但请注意，colType 在这里对您没有用——您无法强制它对应于向量中的类型，因为它只存在于值级别。但这可能没问题，您可能只想从数据结构中完全删除colType，因为您始终可以直接从Column v a 中选择的a 的具体类型派生它。

事实上，Column 类型中的约束也没有起到多大的作用，我认为将它渲染成这样会更好

data Column v a = Column {rawVector :: v a, colName :: Text}

现在您可以在必要时在呼叫站点强制执行 G.Vector 约束...