批处理脚本在带括号的文件名上失败

Question

我写了一个批处理脚本：

@echo off
set "zip=C:\Program Files\7-Zip\7z.exe"
for %%f in (%*) do (
    if exist "%%~f\" (
        "%zip%" a -tzip "%%~f.zip" "%%~f\*" -mx0
    ) else (
        "%zip%" a -tzip "%%~f.zip" %%f -mx0
    )
)

当用户选择多个文件/文件夹并将它们拖到脚本文件中时，拖动的每个文件/文件夹都会打包成一个 zip 文件。

在大多数情况下都可以正常工作。但是，如果被拖动的文件位于文件名包含括号的目录中，例如“myfolder(large)”，则脚本将失败。

谁能告诉这个问题的原因以及如何解决它？

Answer 1

对于这个问题，我看到以下选项：

1. ^ 使用临时变量转义括号：

   @echo off
   set "ZIP=C:\Program Files\7-Zip\7z.exe"
   set "ARGS=%*"
   set "ARGS=%ARGS:^=^^%"
   set "ARGS=%ARGS:&=^&%"
   set "ARGS=%ARGS:(=^(%"
   set "ARGS=%ARGS:)=^)%"
   for %%F in (%ARGS%) do (
       dir /A "%%~fF" | > nul 2>&1 findstr "DIR" && (
           "%ZIP%" a -tzip "%%~F.zip" "%%~F\*" -mx0
       ) || (
           "%ZIP%" a -tzip "%%~F.zip" "%%~fF" -mx0
       )
   )
   

   此方法解决了括号 ( 和 ) 以及 & 和 ^ 的问题，但它对批处理脚本具有特殊含义的所有字符（如 <、@ 987654331@和|。

2. 为有问题的字符串启用和应用delayed expansion：

   @echo off
   set "ZIP=C:\Program Files\7-Zip\7z.exe"
   set "ARGS=%*"
   setlocal EnableDelayedExpansion
   for %%F in (!ARGS!) do (
       endlocal
       dir /A "%%~fF" | > nul 2>&1 findstr "DIR" && (
           "%ZIP%" a -tzip "%%~F.zip" "%%~F\*" -mx0
       ) || (
           "%ZIP%" a -tzip "%%~F.zip" "%%~fF" -mx0
       )
       setlocal
   )
   endlocal
   

   我更喜欢这种方法，因为它解决了所有特殊字符的问题。循环内部延迟扩展的切换（依赖于禁用它的 Windows 默认设置）是为了在扩展 %%F 变量实例期间将其禁用，否则如果字符串包含感叹号 !，则会出现问题。这里的问题是延迟扩展会消耗命令行中遇到的!。像%%F 这样的for 变量在执行延迟扩展之前扩展为其值；因此，如果 %%F 值包含 ! 它会消失 - 除非延迟扩展被禁用，其中 ! 没有特殊含义。