计算一行中的一列等于另一行中的另一列

Question

所以我在下面有一个（简化的）表格。

shift_id	employee_Nbr	begin_dt	end_dt
001	12	1/7/21	1/9/21
002	12	1/9/21	1/14/21
003	15	1/10/21	1/13/21
004	12	1/24/21	1/24/21
005	15	1/13/21	1/14/21

我正在尝试计算同一员工在一行中的end_dt 等于另一行的begin_dt 的次数。在此示例中，计数为 2，因为行 (1&2) 和行 (3&5) 满足此条件。请注意，第 4 行有一个 begin_dt 等于它自己的 end_dt 在这种情况下这对我没有任何意义。我还希望将这些数据放在一个表格中，以便能够回顾而不是简单的计数。有什么建议吗？

Answer 1

这也可以使用哈希表来实现；这可能是最好的选择。它非常快，不需要排序，并且应该可以避免与重复行相关的数据步骤合并可能遇到的一些问题。

data have;
input shift_id $    employee_nbr $  begin_dt :mmddyy8. end_dt :mmddyy8.;
format begin_dt end_dt date9.;
datalines;
001 12  1/7/21  1/9/21
002 12  1/9/21  1/14/21
003 15  1/10/21 1/13/21
004 12  1/24/21 1/24/21
005 15  1/13/21 1/14/21
;
run;


data want;
  set have;
  
  ** Load up a hash table;
  if _n_ = 1 then do;
    declare hash h_enddt(dataset:'have');
    h_enddt.defineKey('employee_nbr','end_dt');  *these are the "unique key" to qualify a record as matching;
    h_enddt.defineData('employee_nbr');          *this is what to "output" when a match is found (basically, nothing here);
    h_enddt.defineDone();
  end;
  
  ** rc is the return code - 0 is "found", nonzero is "not found";
  ** this does a search in the hash table, using employee_nbr and begin_dt values as the match keys;
  ** So, "current record" begin_dt is compared to "hash table" end_dt, and it returns 0 if it is found;
  rc = h_enddt.find(key:employee_nbr,key:begin_dt);
  
  ** Now, output rows if "current record" begin_dt is not equal to "current record" end_dt, and a match is found (rc=0);
  if begin_dt ne end_dt and rc eq 0 then output;
run;

注意 1/24 日期仅通过拒绝 begin_dt = end_dt; 的行来处理。如果您的拒绝规则不同，您可能需要添加其他内容（如行号变量）以确保您没有得到自我匹配。

Answer 2

您可以自行加入此表并在您的唯一键上排除：

select t.*
    , t2.*
    , count(case when t2.shift_id is not null then 1 end) over ()
from t
left join t t2
    on (
        t.begin_dt = t2.end_dt
        or t.end_dt = t2.begin_dt
        )
    and t.employee_Nbr = t2.employee_Nbr
    and t.shift_id <> t2.shift_id

这可以为您提供所有匹配的数据以及匹配的行数，但我不完全确定我理解您在计算什么，所以如果您要计算某些内容，请随时告诉我具体的。

Answer 3

这可以使用 SAS 数据步执行您想要的操作。 如果您使用的是 SAS viya，则可以通过在 CAS 上运行 Data 步骤来避免使用两种 Proc 排序。

它基本上是用ifself加入表，但不包括shift_id相同的情况。

至于实际计数，您可以只检查表有多少观察值，或者如果您想按员工计数，则运行 proc freq。因为不知道，所以不包括在内。告诉我

data have;
infile datalines dlm='09'x;
input shift_id $    employee_Nbr $  begin_dt    $ end_dt $;
datalines;
001 12  1/7/21  1/9/21
002 12  1/9/21  1/14/21
003 15  1/10/21 1/13/21
004 12  1/24/21 1/24/21
005 15  1/13/21 1/14/21
;
run;

proc sort data=have (rename=(begin_dt=matchdate)) out=have1;
by employee_nbr matchdate;
run;

proc sort data=have (rename=(end_dt=matchdate)) out=have2;
by employee_nbr matchdate;
run;

data want;
    merge have1 (in=s1) have2 (in=s2 rename=(shift_id=shift_id2));
    by employee_nbr matchdate;
    if s1 and s2 and shift_id ne shift_id2; *keep if dates match and it is not the same shift;
run;

Answer 4

你似乎想要：

select count(*)
from t join
     t t2
     on t2.employee_Nbr = t.employee_Nbr  and 
        t2.end_dt = t.begin_dt
where t.end_dt <> t.begin_dt and
      t2.end_dt <> t2.begin_dt;