如果工作表 (3) 中的单元格值与工作表 (2) 中的单元格值匹配并且工作表 (2) 中的指定单元格包含给定文本替换为

Question

如果工作表 3 中的单元格值与工作表 2 中的单元格值匹配，并且工作表 2 中的指定单元格包含给定文本替换为...

（编辑 - 评论的附加解释）：我想将 Sheets（“New”）中的 D 列与 Sheets（“alljobs”）中的 A 列进行比较。如果这些匹配，我想转到 Sheets("alljobs") 的 G 列，并根据它是否包含 GTB 或 WDTC，我想将 Sheets("New") 的 B 列更改为 Disney WDTC 或 Disney DCL。

知道为什么它运行但什么都不做吗？

Sub changedisney()

Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Dim wb As Workbook
Dim ws As Worksheet
Dim lookupvalue As Variant

Set wb = ActiveWorkbook
Set ws1 = wb.Sheets("April")
Set ws2 = wb.Sheets("alljobs")
Set ws3 = wb.Sheets("New")

y = ws3.Cells(ws3.Rows.Count, 2).End(xlUp).Row
    For i = y To 2 Step -1
        lookupvalue = ws3.Cells(i, 4)
        For x = ws2.Cells(Rows.Count, 4).End(xlUp).Row To Step - 1
            Set rng = ws2.Cells(x, 4)
            If rng = lookupvalue And ws2.Cells(x, 7) Like "wdtc*" Then
                ws3.Cells(x, 2) = "Disney WDTC"
            End If
        Next x
    Next i


Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

Answer 1

这样的东西应该适合你：

Sub changedisney()

    Dim wb As Workbook
    Dim wsAll As Worksheet
    Dim wsNew As Worksheet
    Dim DCell As Range
    Dim rFound As Range

    Set wb = ActiveWorkbook
    Set wsAll = wb.Sheets("alljobs")
    Set wsNew = wb.Sheets("New")

    For Each DCell In wsNew.Range("D2", wsNew.Cells(Rows.Count, "D").End(xlUp)).Cells
        Set rFound = wsAll.Columns("A").Find(DCell.Value, , xlValues, xlWhole)
        If Not rFound Is Nothing Then
            Select Case LCase(Left(wsAll.Cells(rFound.Row, "G").Text, 3))
                Case "wdt": wsNew.Cells(DCell.Row, "B").Value = "Disney WDTC"
                Case "gtb": wsNew.Cells(DCell.Row, "B").Value = "Disney DCL"
            End Select
        End If
    Next DCell

End Sub

编辑：根据 OP 的评论更新代码：

我想将 wsNew 中的 D 列与 wsALL 中的 A 列进行比较。如果这些 匹配我想去 wsNew 的 G 列 并取决于是否 它包含 GTB 或 WDTC，我想将 wsNew 的 B 列更改为说 迪士尼 WDTC 或迪士尼 DCL

（在您的评论中，您声明查看 wsNew 的 G 列，但我认为您的意思是说 wsAll 的 G 列，这是更新后的代码所做的。）