如何在没有特定标头的 mulesoft 中的 Dataweave 2.0 中将 CSV 转换为 JSON？

Question

我有没有标题的 CSV 输入文件

输入示例如下

ETM, St. Petersburg
Date: 03/28/12
Number: 14.P3.11.12032818-1
Note:
LON 95w B-230-95-4 E27; 305003311; pcs; 30800; order; 322233.1; KP14278
DSh 60w DSh-230-60 E14; S0100325; pcs; 576; order; 322233.1; KP14278
DSh 40w DSh-230-40 E14; 321600316; pcs; 576; order ;; KP14278
LON 60w B-230-60-4 E27; 303456500; pcs; 16940; order ;; KP14278

预期的输出应该是这种 JSON 格式

预期的基本结构

{
  "orders": {
    "location": "",
    "deliveryDate": "",
    "orderNo": "",
    "Notes": ""
  },
  "ordersItems": {
    "itemsDetails": [
      {
        "materialdetails": "LON 95w B-230-95-4 E27",
        "referenceNo": "305003311",
        "uom": " pcs",
        "qty": " 30800",
        "docType": " order",
        "projectCode": " 322233.1",
        "description": " KP14278"
      },
      .....
      ...... 
    ]
  }
}

Answer 1

我同意@aled，这看起来不像一个正确的 CSV 文件，但如果您只想解析从第 5 行开始的数据，您可以执行以下操作：

%dw 2.0
output application/json
var data = "ETM, St. Petersburg
Date: 03/28/12
Number: 14.P3.11.12032818-1
Note:
LON 95w B-230-95-4 E27; 305003311; pcs; 30800; order; 322233.1; KP14278
DSh 60w DSh-230-60 E14; S0100325; pcs; 576; order; 322233.1; KP14278
DSh 40w DSh-230-40 E14; 321600316; pcs; 576; order ;; KP14278
LON 60w B-230-60-4 E27; 303456500; pcs; 16940; order ;; KP14278"

var fs = {
    column_0: "materialDetails",
    column_1: "referenceNo",
    column_2: "uom",
    column_3: "qty",
    column_4: "docType",
    column_5: "projectCode",
    column_6: "description"
}

var parsedRows = read(
    data, 
    "application/csv", 
    {separator: ";",header: false,bodyStartLineNumber: 5}
)

---
{
    orders: {
        location: "",
        deliveryDate: "",
        orderNo: "",
        Notes: ""
    },
    ordersItems: {
        itemsDetails: parsedRows map ($ mapObject {(fs[$$]): $})
    }
}

注意，我将数据设置在一个字符串中（主要是因为我希望我的代码是独立的）并使用read() 函数进行解析。您可以执行类似的操作并跳过文件中的额外行。