如何在 mule 3 中声明局部变量

Question

我正在 Mule 3 中进行数据转换。我正在更新现有代码，其中在 DataWeave 1.0 中声明了许多变量

我想在声明的变量中添加一个名为“type__c”的字段。

我的输入载荷如下

{
  "billofPlaning": {
    "billcollection": {
      "itemDetail": [
        {
          "comm": [
            {
              "commodity": {
                "itemSequence": 1,
                "equipmentPrefix": "ABCD",
                "equipmentNumber": "1234"
              }
            },
             {
              "commodity": {
                "itemSequence": 2,
                "equipmentPrefix": "DEFG",
                "equipmentNumber": "5678"
              }
            }
          ]
        }
      ]
    },
       "equip": [
      {
        "equipment": {
          "prefix": "ABCD",
          "number": "1234",
          "type": 2345
        }
      },
       {
        "equipment": {
          "prefix": "HIJ",
          "number": "7890",
           "type": 234567
        }
      }
    ]
  }
}

我现有的 DataWeave 1.0 脚本是这样的：

%dw 1.0
%output application/java
%var inputData=payload
%var payBill= inputData.billofPlaning.billcollection.itemDetail default [] map (billcode,indexOfbillcode) -> {
    billcode: {
            "field1": "",
            "type__c": ""
        }
---
paybill

我想在上面的 DataWeave 1.0 代码中为字段“type__c”重用下面的 DataWeave 2.0 代码。

%dw 2.0
output application/json
var test= ((payload.billofPlaning.equip) filter (($.equipment.prefix == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentPrefix[0])
and ($.equipment.number == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentNumber[0])))
---
"type__c": test.equipment."type"[0]

我们能否使用 DataWeave 1.0 以更好的方式来做这件事（基本上使用任何局部变量或我们在 DataWeave 1.0 中声明的 payBill 变量中的某些东西）？

Answer 1

目前尚不清楚您的转换逻辑是什么以及预期的结果是什么。如果您只想重用test 变量，那么DataWeave 1 和DataWeave 2 之间特定变量的唯一区别在于前者的变量声明使用% 字符。我将它添加到脚本中并删除了无用的 inputData 变量。我还修复了缺少结束大括号的脚本。

%dw 1.0
%output application/java
%var test= ((payload.billofPlaning.equip) filter (($.equipment.prefix == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentPrefix[0])
and ($.equipment.number == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentNumber[0])))        

%var payBill=(payload.billofPlaning.billcollection.itemDetail default []) 
        map (billcode,indexOfbillcode) -> {
          billcode: {
            "field1": "",
            "type__c":  test
          }
        }
---
payBill

输出：

[{billcode={field1=, type__c=[{equipment={prefix=ABCD, number=1234, type=2345}}]}}]

如果您想定义一个“本地”变量，您可以使用using 语法来声明scoped variables。我看不出在这个特定的脚本中这有什么意义。通常它用于简化对嵌套项的访问，此脚本不使用。

例子：

%dw 1.0
%output application/java
%var payBill=(payload.billofPlaning.billcollection.itemDetail default []) 
        map (billcode,indexOfbillcode) -> 
          using ( test= ((payload.billofPlaning.equip) filter (($.equipment.prefix == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentPrefix[0])
and ($.equipment.number == payload.billofPlaning.billcollection.itemDetail.comm[0].commodity.equipmentNumber[0])))    )        

          {
            billcode: {
              "field1": "",
              "type__c":  test
            }
          }
---
payBill

我不会称之为改进。

DataWeave 2.0 中的等效项是 do 命令，它具有改进的功能和更好的语法。