如果崩溃，请重新启动 vbs 脚本

Question

我正在尝试制作一个 vb 脚本，如果它崩溃，它将重新启动另一个 vb 脚本。 我已经搜索过，但我得到的只是如何重新启动程序，并且由于 vb 脚本是后台进程，因此在 Win32_Process 中搜索时它不起作用。

这是我的代码

set Service = GetObject ("winmgmts:")
set Shell = WScript.CreateObject("WScript.Shell")

sEXEName = "Test_To_Block.vbs"

while true
 bRunning = false

 for each Process in Service.InstancesOf ("Win32_Process")
  if Process.Name = sEXEName then
   bRunning=true
   msgbox("I am active")
  End If
 next


if bRunning=False then
 msgbox("I am not active.")
 Shell.Run sEXEName
end if


WScript.Sleep(100)

wend

问题是它永远看不到文件正在运行，只是打开了数百个“Test_To_Stop.vbs”，这解决了我不得不重新启动计算机的问题。

在我看来，应该改变的是代码在哪里寻找。

for each Process in Service.InstancesOf ("Win32_Process")

您需要查看后台进程运行的位置，而不是查看“Win32_Process”。

我是编码新手，如果这是一个简单的问题，我很抱歉。

提前谢谢你。

问候，

毒蛇

Answer 1

以下代码通过WshShell.Exec() 方法自行重启，并通过返回对象的.Status 属性跟踪运行脚本的状态：

If Not WScript.Arguments.Named.Exists("task") Then
    Do
        With CreateObject("WScript.Shell").Exec("""" & WScript.FullName & """ """ & WScript.ScriptFullName & """ ""/task""")
            Do While .Status = 0
                WScript.Sleep 1
            Loop
        End With
    Loop
End If

MsgBox "This script will be restarted immediately after termination"

另一种方法是使用.Run() 方法，将第三个参数设置为True 等待启动的进程终止：

If Not WScript.Arguments.Named.Exists("task") Then
    Do
        CreateObject("WScript.Shell").Run """" & WScript.FullName & """ """ & WScript.ScriptFullName & """ ""/task""", 1, True
    Loop
End If

MsgBox "This script will be restarted immediately after termination"

甚至更简单：

If Not WScript.Arguments.Named.Exists("task") Then
    Do
        CreateObject("WScript.Shell").Run """" & WScript.ScriptFullName & """ ""/task""", 1, True
    Loop
End If

MsgBox "This script will be restarted immediately after termination"

Answer 2

可能是因为正在运行的进程的名称是“wscript.exe”而不是“Test_To_Block.vbs”。您也许可以使用this 页面上提到的 hack 来更改进程的名称：

如果您在本地运行脚本并运行一些常规脚本，则一个 常见的 hack 只是将 wscript.exe 复制并重命名为特定名称， 例如“MyScript1.exe”。然后使用快捷方式运行脚本 “...\MyScript1.exe MyScript1.vbs”。然后该过程将显示为 MyScript1.exe。

那你可以使用sEXEName = "MyScript1.exe"

注意：不要使用Shell.run sExeName，而是使用Shell.run "Test_To_Block.vbs"