如何在 Delphi 中显示 XMPP (Jabber) 电子名片照片？

Question

如何从 XMPP vcard（头像图片，我认为是 JPEG 格式）中读取照片并将其显示在 Delphi TImage 控件中？

XMPP 服务器发送这个 XML：

<presence id="e3T50-75" to="cvg@esx10-2022/spark" from="semra@esx10-2022" 
 type="unavailable">
  <x xmlns="vcard-temp:x:update">
    <photo>897ce4538a4568f2e3c4838c69a0d60870c4fa49</photo>
  </x>
  <x xmlns="jabber:x:avatar">
    <hash>897ce4538a4568f2e3c4838c69a0d60870c4fa49</hash>
  </x>
</presence>

Answer 1

您发布的 XML 不包含图片。它包含图片内容的SHA-1 hash。最初，您只会获得哈希值，以防您之前已经获取过该图像一次，因此您可以显示缓存版本而不是重新请求它。

如果您没有包含该哈希的图像，请申请新的 vcard。当它到达时，请阅读PHOTO 元素（如果可用）。它可能有两个子元素BINVAL 和TYPE。 BINVAL 将包含图像的 Base-64 编码版本，TYPE 将包含图像类型的 MIME 类型标识符，例如 image/jpeg 或 image/png .

解码二进制数据并将其存储在流中，例如TFileStream 或TMemoryStream。接下来，选择适合您拥有的图像类型的TGraphic 后代。可能是TPngImage，也可能是TBitmap。实例化该类，并告诉它加载流的内容。它会是这样的：

function CreateGraphicFromVCardPhoto(const BinVal, MimeType: string): TGraphic;
var
  Stream: TStream;
  GraphicClass: TGraphicClass;
begin
  Stream := TMemoryStream.Create;
  try
    if not Base64Decode(BinVal, Stream) then
      raise EBase64Decode.Create;
    Stream.Position := 0;
    GraphicClass := ChooseGraphicClass(MimeType);
    Result := GraphicClass.Create;
    try
      Result.LoadFromStream(Stream);
    except
      Result.Free;
      raise;
    end;
  finally
    Stream.Free;
  end;
end;

上面的代码使用来自OmniXML 的Base64Decode 函数，在Saving a Base64 string to disk as a binary using Delphi 2007 的答案中描述。获得TGraphic 值后，您可以将其分配给TImage 或使用TGraphics 执行任何其他操作。

ChooseGraphicClass 函数可能像这样工作：

function ChooseGraphicClass(const MimeType: string): TGraphicClass;
begin
  if MimeType = 'image/bmp' then
    Result := TBitmap
  else if MimeType = 'image/png' then
    Result := TPngImage
  else if MimeType = 'image/gif' then
    Result := TGifImage
  else if MimeType = 'image/jpeg' then
    Result := TJpegImage
  else
    raise EUnknownGraphicFormat.Create(MimeType);
end;