【问题标题】:Improve SPARQL for the time range在时间范围内改进 SPARQL
【发布时间】:2019-04-11 21:18:07
【问题描述】:

我正在尝试使用 python 编程制作一些 sparql 查询语句,但我被困在下面。我正在尝试以某种通用方式查询时间范围的语句。下面给我一个例子。问题是"Who was the mayor of the new york city in %(YEAR)?",我写的对应的sparql如下。对于之前的范围,它可以正常工作。但是最近的范围,它不起作用,因为现任市长没有结束时间。换句话说,我可以制作类似 FIlTER (?v3 has no value or ?v3 > "2011-01-01"^^xsd:dateTime) 的代码吗?我想通过一个与时间范围问题相对应的更通用方式的查询来改进我的 sparql。

案例 1:谁是 2011 年纽约市的市长? -好的

SELECT DISTINCT ?v ?vLabel ?v2 ?v3
WHERE
{
  wd:Q60 p:P6 ?stmt.
  ?stmt  ps:P6 ?v;
         pq:P580 ?v2;
         pq:P582 ?v3.
  FILTER (?v2 < "2011-01-01"^^xsd:dateTime) # start time
  FILTER (?v3 > "2011-01-01"^^xsd:dateTime) # end time

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
ORDER BY DESC (?v2)

案例 2:谁是 2016 年纽约市的市长? - 没有答案

SELECT DISTINCT ?v ?vLabel ?v2 ?v3
WHERE
{
  wd:Q60 p:P6 ?stmt.
  ?stmt  ps:P6 ?v;
         pq:P580 ?v2;
         pq:P582 ?v3
  FILTER (?v2 < "2016-01-01"^^xsd:dateTime) # start time
  FILTER (?v3 > "2016-01-01"^^xsd:dateTime) # end time

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
ORDER BY DESC (?v2)

【问题讨论】:

    标签: sparql wikidata


    【解决方案1】:

    第 1 步:获取要匹配的查询模式,即使“结束时间”没有值。这可以使用 OPTIONAL 来完成三重模式:

    OPTIONAL { ?stmt pq:P582 ?v3 }
    

    第 2 步:更改过滤器,使其接受结束时间变量 ?v3 没有值的解决方案。这可以使用bound 函数来完成,如果有值则返回true,否则返回false:

    FILTER (!bound(?v3) || ?v3 > "2016-01-01"^^xsd:dateTime) # end time
    

    完整查询:

    SELECT DISTINCT ?v ?vLabel ?v2 ?v3
    WHERE
    {
      wd:Q60 p:P6 ?stmt.
      ?stmt  ps:P6 ?v;
             pq:P580 ?v2.
      OPTIONAL { ?stmt pq:P582 ?v3 }
      FILTER (?v2 < "2016-01-01"^^xsd:dateTime) # start time
      FILTER (!bound(?v3) || ?v3 > "2016-01-01"^^xsd:dateTime) # end time
    
      SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
    }
    ORDER BY DESC (?v2)
    

    【讨论】:

    • 哦,我明白了。我对BOUND一无所知。非常感谢。
    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2019-04-12
    • 2014-07-23
    • 2023-03-03
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多