MVC.Net - 缓存用户对象为应用程序提供数据（问总结）

Question

我非常感谢一些建议，以帮助我进行对象缓存。 这是我的需求：我想根据存储在 SQL 数据库中的用户角色过滤控制器的一些操作。

我现在正在做的是：当当前用户的第一个请求完成时，我会生成一个具有一些由 SQL 查询初始化的属性的对象。我正在使用自定义提供程序将此对象存储到会话中，并且我正在使用自定义角色提供程序来处理授权过滤器标签。如果会话过期用户被重新生成.. 它是这样的（简化）：

用户类

Public class User

   public property Login as string
   public property IsAdmin as boolean

   public sub Init(byval pLogin as string)
        Login = pLogin
        //Do some logic on database to provides roles....
        IsAdmin = dbReturnIsAdmin
   end sub

   public readonly property RolesList as string()
       Get
          Return New String() {If(IsAdmin, "UserIsAdmin", "")}
       End get
   end property 

End class

会话用户提供者

Public Class SessionProvider

   Private Const SESSION_USER As String = "SESSION_USER"

    Public Shared Sub ReloadUser()
        //'This instruction initiate user and load roles into an User class type object
        HttpContext.Current.Session(SESSION_USER) = StructureService.GetInitializedUser(My.User.Name, UowProvider.StructureUow)
    End Sub

    Public Shared ReadOnly Property User() As Application.User
        Get
            //'If user doesn't exist so we create an user

            If HttpContext.Current.Session(SESSION_USER) Is Nothing Then ReloadUser()

            //'Return user
            Return CType(HttpContext.Current.Session(SESSION_USER), Application.User)
        End Get
    End Property

End Class

自定义角色提供者

Public Class AuthentifiedRoleProvider
    Inherits RoleProvider
    //Implement base role provider....

    Public Overrides Function GetRolesForUser(username As String) As String()
        return SessionProvider.User.RolesList
    End Function

End Class

实施 - WebConfig

    <system.web> .....
     <roleManager cacheRolesInCookie="false" defaultProvider="DefaultRoleProvider" enabled="true">
         <providers>
             <clear />
             <add name="DefaultRoleProvider" type="AuthentifiedRoleProvider" />
         </providers>
     </roleManager>     
   </system.web>

实现 - 控制器

    <Authorize(Roles:="UserIsAdmin")>
    Public Function List_Items() As ActionResult
        Return View()
    End Function

它正在工作......

但是，我想知道这是否真的是实现这一目标的好方法。 由于我的应用程序上有一个站点地图引用控制器操作，因此每次菜单加载都会请求 sessionprovider 用户（顺便说一下 http 会话）4 或 5 次。

所以，我的问题是：

• 存储到会话中会带来性能问题吗？
• 有没有更好的方法将我的用户对象存储到一种缓存中（--> 我想到了 system.runtime.cache）。
• 不管怎样，你认为这个实现对实现我的目标有好处吗？

非常感谢！

Answer 1

不管怎样，你认为这个实现对实现我的目标有好处吗？

可能不会。

1. 出于某种原因，您将会话状态绑定到用户配置文件数据。会话状态与授权/身份验证无关，它是not recommended to use it for User Profile data，因为使用会话状态（在任何实际意义上）意味着您将需要 2 个额外的网络请求每个 HTTP 请求到您的应用程序。此外，无论用户是否登录，这些额外请求都会发生。
2. MvcSiteMapProvider 不依赖会话状态。它使用共享缓存将节点存储在 RAM 中，并使用 AuthorizeAttribute 来确定每个请求要显示/隐藏哪些节点。

如果您发现每次请求多次请求相同的数据，您应该尝试通过使用类似于以下的标准缓存检索模式来利用 请求缓存 (HttpContextBase.Items)：

Public Function GetSomeData() As ISomeData
    Dim key As String = "SomeDataKey"
    ' Me.cache refers to HttpContextBase.Items injected through 
    ' the constructor of this class and stored in a private field
    Dim someData As ISomeData = TryCast(Me.cache(key), ISomeData) 
    If someData Is Nothing Then
        ' The data is not cached, so look it up and populate the cache
        someData = GetDataFromExternalSource()
        Me.cache(key) = someData
    End If
    Return someData
End Function

将这样的方法放入组件之间共享的服务中意味着您不必担心在请求中多次检索相同的数据 - 第一次会访问外部源，并且每次都会访问将使用缓存。

另外，根据MSDN：

创建自定义角色提供者有两个主要原因。

1. 您需要将角色信息存储在不受 .NET Framework 包含的角色提供程序支持的数据源中，例如 FoxPro 数据库、Oracle 数据库或其他数据源。
2. 您需要使用与 .NET Framework 附带的提供程序所使用的数据库架构不同的数据库架构来管理角色信息。一个常见的例子是公司或网站的 SQL Server 数据库中已经存在的角色数据。

因此，如果您不做这些事情中的任何一个，那也可能不是正确的选择。大多数现代应用程序可以使用/扩展ASP.NET Identity 进行用户身份验证，所有MVC 应用程序都应使用AuthorizeAttribute（或其子类）进行授权。

System.Runtime.Cache.ObjectCache（和MemoryCache）是缓存用户之间通常不共享的数据的好方法。如果您将缓存键设计为包含用户的唯一标识符以及使键唯一的分隔符，则可以将其用于用户数据...

Dim key As String = UserId & "|UserProfile"

也就是说，您应该知道，这种缓存方式不会扩展到多个服务器。

无论如何，我建议您遵循think twice about using Session State 中的建议。在许多情况下，MVC 使我们不必使用 Session 状态——除非绝对需要，否则我们不应该使用它。

Answer 2

感谢建议，我已将会话用户提供程序更改为使用缓存。它必须扩展，但现在我可以看到变化！

会话用户提供者

   Public Class UserProvider


    Private Const USER_CACHE_PREFIX As String = "User|"

    Private Shared Sub AddUserToCache(ByVal pLogin As String, ByVal pUser As Application.User)
        Dim objCache As ObjectCache = MemoryCache.Default
        objCache.Add(USER_CACHE_PREFIX & pLogin, pUser, New CacheItemPolicy With {.SlidingExpiration = TimeSpan.FromSeconds(20)})
    End Sub

    Private Shared Function GetUserFromCache(ByVal pLogin As String) As Application.User
        Dim objCache As ObjectCache = MemoryCache.Default
        //Return cache if exists
        If objCache.Contains(USER_CACHE_PREFIX & pLogin) Then
            Return CType(objCache.GetCacheItem(USER_CACHE_PREFIX & pLogin).Value, Application.User)
        Else
            Return Nothing
        End If
    End Function

    Public Shared Function ReloadUser(ByVal pLogin As String) As Application.User
        Dim objCache As ObjectCache = MemoryCache.Default
        Dim tmpLogin As String = My.User.Name
        //Clear cache
        If objCache.Contains(USER_CACHE_PREFIX & tmpLogin) Then objCache.Remove(USER_CACHE_PREFIX & pLogin)
        Dim tmpUser As Application.User = StructureService.GetInitializedUser(pLogin, UowProvider.StructureUow) 
        AddUserToCache(tmpLogin, tmpUser)
        return tmpUser
    End Function

    Public Shared ReadOnly Property User() As Application.User
        Get
            Dim tmpLogin As String = My.User.Name
            //Try to get user from cache
            Dim tmpUser As Application.User = GetUserFromCache(tmpLogin)
            //If user is null then init and cache
            If tmpUser Is Nothing Then
                tmpUser = StructureService.GetInitializedUser(tmpLogin, UowProvider.StructureUow) 
                AddUserToCache(tmpLogin, tmpUser)

            End If

            //return  user
            Return tmpUser
        End Get
    End Property

End Class