密码查询以找到将汤姆汉克斯介绍给汤姆克鲁斯的“最佳”人选

Question

我正在浏览neo4j 3.0.6 Movie Graph 示例，并且正处于我们“找人将汤姆汉克斯介绍给汤姆克鲁斯”的部分。 执行后

MATCH (tom:Person {name:"Tom Hanks"})-[:ACTED_IN]->(m)<-[:ACTED_IN]-(coActors),
      (coActors)-[:ACTED_IN]->(m2)<-[:ACTED_IN]-(cruise:Person {name:"Tom Cruise"})
RETURN tom, m, coActors, m2, cruise

我得到以下图表：

哪个 Cypher 查询会根据与汤姆·汉克斯和汤姆·克鲁斯的关系最密切的人优先对合作演员进行排名？结果类似于：

Name        , connecting_movies, (OR) connecting_edges
Meg Ryan    , 4                , 8
Bonnie Hunt , 2                , 4
Kevin Bacon , 2                , 4

Answer 1

由于您只查看一种关系类型 (:ACTED_IN)，因此使用常见电影的数量并忽略边缘应该就足够了（边缘无论如何都是电影数量的 2 倍，除非其中一位演员扮演多个同一部电影中的角色，但这似乎不是衡量更紧密联系的有意义的衡量标准）。

但是，我们必须确保在获得计数时只考虑不同的电影，因为可能有一部电影由所有相关人员（汤姆、汤姆和合作者）出演，而我们只希望数那部电影一次，而不是两次。为了确保我们获得不同的计数，我们需要将两列电影（m 和 m2）合并到一个列中，然后在该列中获得不同的电影计数。

不幸的是，此时 Neo4j 的 UNION 不允许我们继续处理联合结果（以获取计数），因此我们必须将电影的每一列变成一个集合，将集合相加，然后将该单个集合展开为单个电影列。最终查询如下所示：

MATCH (:Person {name:"Tom Hanks"})-[:ACTED_IN]->(m)<-[:ACTED_IN]-(coActors)
MATCH (coActors)-[:ACTED_IN]->(m2)<-[:ACTED_IN]-(:Person {name:"Tom Cruise"})
WITH coActors, collect(m) + collect(m2) as allMovies
UNWIND allMovies as moviesInCommon
RETURN coActors, COUNT(DISTINCT moviesInCommon) as commonMoviesCnt
ORDER BY commonMoviesCnt DESC

编辑我将您的第一个 MATCH 更改为两个 MATCHES，因为在单个匹配行中，m 中的电影不会在 m2 中匹配（我鼓励您将描述中的查询也更改为 2 个匹配）。虽然这会给我们带来不同的计数（我们想要的东西），但它也会阻止我们正确匹配在同一部电影中与两个感兴趣的演员一起表演的合作演员。

您可以通过将感兴趣的人更改为 Tom Hanks 和 Meg Ryan 来测试这一点。当然，他们已经认识，不需要介绍，但是使用这两个可以更好地显示当两个演员在同一部电影中合作时，哪些查询是正确的。

Answer 2

[更新]

您的单个​​MATCH 子句强制m 和m2 计数始终相同，这意味着对于特定的coActor，m 或m2 节点可以出现多次。为避免这种重复，您可以将其拆分为 2 个MATCH 子句并分别获取计数，如下所示。此查询还会过滤掉两位汤姆都出演过的电影，因为这意味着不再需要介绍它们。

MATCH (a1:Person {name:"Tom Hanks"}), (a2:Person {name:"Tom Cruise"})
MATCH (a1)-[:ACTED_IN]->(m1)<-[:ACTED_IN]-(coActor)
WHERE NOT (a2)-[:ACTED_IN]->(m1)
WITH a1, a2, coActor, COUNT(m1) AS c1
MATCH (coActor)-[:ACTED_IN]->(m2)<-[:ACTED_IN]-(a2)
WHERE NOT (a1)-[:ACTED_IN]->(m2)
WITH coActor, (c1 + COUNT(m2)) AS connecting_movies
RETURN coActor.name AS name, connecting_movies, 2*connecting_movies AS connecting_edges
ORDER BY connecting_movies DESC;