如何在嵌套的哈希图中合并？

Question

我有一个嵌套的 hashmap，其结构如下：

(def pathmap {:order {:genus {:species {:cat2 "data", :cat1 "data"}}}})

我需要的是一个类似 assoc-in 的函数，它允许我将新的键值对添加到最里面的嵌套映射中，而不是简单地替换已经存在的内容。例如：

(my-assoc-merge pathmap [:order :genus :species] {:cat3 "data"})
;=> {:order {:genus {:species {:cat3 "data" :cat2 "data", :cat1 "data"}}}}

我想我可以通过稍微改变 assoc-in 函数来使用 merge-with 和 union 来轻松做到这一点：

(defn my-assoc-merge
  [m [k & ks] v]
  (if ks
    (assoc m k (my-assoc-merge (get m k) ks v))
    (assoc m k (merge-with clojure.set/union (get m k '{}) v))))

不幸的是，这给了我错误“CompilerException java.lang.UnsupportedOperationException：此类型不支持计数：关键字，编译：（core.clj:34:12）”。我哪里错了？

Answer 1

实际上，assoc-in 已经创建了一个新密钥，如果它不存在的话。用法如下：

(def pathmap {:order {:genus {:species {:cat2 "data", :cat1 "data"}}}})

(assoc-in pathmap [:order :genus :species :cat3] "data")
;=> {:order {:genus {:species {:cat2 "data", :cat3 "data", :cat1 "data"}}}}

如果您希望合并新地图，请使用 update-in 和 merge

(update-in pathmap [:order :genus :species] merge {:cat3 "data"})
;=> {:order {:genus {:species {:cat2 "data", :cat3 "data", :cat1 "data"}}}}

您的my-assoc-merge 的问题在于union 可以在集合上使用。将merge-with 更改为merge 并删除union。