如何在 Prolog 中创建这个 DCG？

Question

我想创建一个 DCG，这样的语言可以被接受：

• c
• bbbcbbb
• bbacbba
• 蕉麻
• aababacaababa

如您所见，这意味着 a 和 b 有一个特定的顺序，然后是一个 c，然后又是与 c 之前完全相同的顺序。如果不满足这些条件，它将失败。

我目前正在这里使用我的方法（有效，但也能识别错误的单词）

s --> x, s, x. 
s --> [c]. 
x --> [a]. 
x --> [b]. 

你们中的任何人可以帮我解决我需要改变的地方吗？我不知道怎么继续。非常感谢。

Answer 1

DCG 实际上只是一个 Prolog 程序，经过预处理添加实现差异列表的隐藏参数。我们总是可以添加自己的参数，并使用模式匹配。那么

s --> ab(X), [c], ab(X). 
ab([a|T]) --> [a], ab(T).
ab([b|T]) --> [b], ab(T).
ab([]) --> [].

?- atom_chars(aababacaababa,Cs),phrase(s, Cs).
Cs = [a, a, b, a, b, a, c, a, a|...] 

Answer 2

您所描述的语言既不是常规的，也不是上下文无关的。因此，您需要求助于 DCG 中提供的 Prolog 扩展。您可能会习惯一些成语：

% any sequence

seq([]) -->
   [].
seq([E|Es]) -->
   [E],
   seq(Es).

使用这个非终结符，我们可以描述一个重复并由一个字符分隔的序列：

rep(Seq, Sep) --> 
   seq(Seq),
   [Sep],
   seq(Seq).

这显然太笼统了。你只想要ab 和c。您现在可以添加更多要求：

rep(Seq, Sep) -->
   seq(Seq),
   {phrase(abs,Seq)},
   [Sep],
   seq(Seq).

 abs --> [] | ("a"|"b"), abs.

那么现在：

 s -->
     rep(_,c).

另一种方法是“硬编码”语法，正如@CapelliC 所示。使用seq//1 使该方法更加灵活。

在字符列表中使用双引号非常方便。 请参阅this answer 如何允许使用双引号来表示字符列表。