XSLT：获取具有特定子元素且没有文本的元素

Question

您好，我有一个 xml 文件如下：

<root>
    <body>
        <place attr="1" id="1" ref="www.example.com">
            <name>abc
            </name>
        </place>
        <place attr="1" id="2" ref="www.example.com">
            <name>def
            </name>
        </place>
        <place attr="2" id="3">
            <place attr="3" id="4" ref="www.example.com">
                <name>efg
                </name>
            </place>
        </place>
    </body>
</root>

我想获取所有元素 <place> 有一个子 <name> 并且元素之间没有文本。

我想要的输出是这样的：

<root>
   <place attr="1" id="1" ref="www.example.com" />
   <place attr="1" id="2" ref="www.example.com" />
   <place attr="3" id="4" ref="www.example.com" />
</root>

我的 xsl 代码返回所有 <place> 标签（我不想要）+ <name> 标签之间的文本：

   <xsl:template match="root">       
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/> 
        </xsl:copy>
    </xsl:template>

   <xsl:template match="place">       
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/> 
        </xsl:copy>
    </xsl:template>

xml 输出：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <place attr="1" id="1" ref="www.example.com">abc</place>
   <place attr="1" id="2" ref="www.example.com">def</place>
   <place attr="2" id="3">
      <place attr="3" id="4" ref="www.example.com">efg</place>
   </place>
</root>

Answer 1

关键是你的apply-templates 声明。

正如您所说，您“只想要 <place> 标记作为孩子的 <name>”。所以你应该只选择那些。

您当前的代码：

<xsl:template match="root">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

当您只使用<xsl:apply-templates/> 时，这与说“将模板应用于此下的*everything*”相同。所以你最终会捕捉到那些你不想要的<place>元素。

为了更有选择性并得到您想要的，我们可以改为：

<xsl:apply-templates select="descendant::place[name]"/>

打破一切

我们使用select 语句来进行选择。 :) 我们不想将模板应用于所有事物，而只是应用于特定事物，这就是我们指定哪些事物的方式。

我们使用descendant:: 轴是因为我们想要捕获包含在<root> 元素（即其后代）中的所有<place> 元素。如果我们只说select="place[name]"，那将意味着“仅将模板应用于作为此<root> 元素的直接子元素的那些<place> 元素。因为没有任何<place> 元素是此@ 的直接子元素987654336@ 元素，这对你没有任何用处。

我们使用[name] 谓词来指定我们只想要具有<name> 子元素的<place> 元素的条件。这让我们可以排除 <place attr="2" id="3">，它包含另一个 <place>，但没有任何自己的 <name> 子代。

我希望这会有所帮助。如果这里有什么不明白的地方请评论。

更新：完整的工作示例

我错误地估计了我之前的答案中包含多少细节。 :)

这是一个完整的工作示例，带有注释。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="1.0">

    <!-- Start at the logical root / since every XSLT *must* start there. -->
    <xsl:template match="/">
        <!-- We just pass everything along.  NOTE: We NEED to define templates
            for anything special we want to do, beyond just the default 
            XSLT behavior of outputting the string contents minus any elements. -->
        <xsl:apply-templates/>
    </xsl:template>

    <!-- We want to get the <root> element and attributes in our output, so
        we define a template to do that.-->
    <xsl:template match="root">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <!-- We also want to process the content of <root>, so we use 
                `xsl:apply-templates`.  Since we also want to be _selective_
                about what we process, we also specify a `select` statement
                with the XPath needed to identify what we want.  
                Again, we NEEd to define a template to process this,
                or we'll just get the text string content and none of 
                the elements.  -->
            <xsl:apply-templates select="descendant::place[name]"/>
        </xsl:copy>
    </xsl:template>

    <!-- Here we define what to do with the <place> elements that have
        <name> children.  Since your <place attr="2" id="3"> element
        has no <name> child, it gets omitted from the output. -->
    <xsl:template match="place[name]">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
        </xsl:copy>
    </xsl:template>

    <!-- Lastly, we define one more template that says "capture everything 
        else, and *don't* output anything".  This way, we don't get the text 
        string output of anything we haven't explicitly defined above. -->
    <xsl:template match="*"/>

</xsl:stylesheet>

我们只得到想要的元素，没有它们包含的文本。

Answer 2

要获得请求的输出，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/root">
    <xsl:copy>
        <xsl:for-each select=".//place[name]">
            <xsl:copy>
                <xsl:copy-of select="@*"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 3

首先，您需要了解XSLT process model：从输入文档的文档根开始，处理器尝试将此节点与某个模板的模式描述的某些规则匹配。还有一些built-in rules：基本上是逐级遍历输入文档，按文档顺序从头到尾遍历。

这就是为什么您需要一个复制root 和place 元素的规则，以及一个不输出文本节点的规则。

有了这个输入

<root>
    <body>
        <place attr="1" id="1" ref="www.example.com">
            <name>abc
            </name>
        </place>
        <place attr="1" id="2" ref="www.example.com">
            <name>def
            </name>
        </place>
        <place attr="2" id="3">
            <place attr="3" id="4" ref="www.example.com">
                <name>efg
                </name>
            </place>
        </place>
    </body>
</root>

这个样式表

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="root|place[name]">
        <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text()"/>
</xsl:stylesheet>

输出

<root>
    <place attr="1" id="1" ref="www.example.com" />
    <place attr="1" id="2" ref="www.example.com" />
    <place attr="3" id="4" ref="www.example.com" />
</root>