CMAKE 中的操作系统特定说明：如何？

Question

我是 CMAKE 的初学者。下面是一个简单的 cmake 文件，它在 mingw 环境窗口中运行良好。问题显然出在我正在链接 libwsock32.a 的 CMAKE 的 target_link_libraries() 函数上。在 Windows 中，这是可行的，我得到了结果。

但是，正如预期的那样，在 Linux 中，/usr/bin/ld 将查找在 Linux 操作系统上不存在的-lwsock32。

我的问题是：如何指示 CMAKE 避免在 Linux 操作系统中链接 wsock32 库？？？

任何帮助将不胜感激。

我的简单 CMake 文件：

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

Answer 1

使用

if (WIN32)
    #do something
endif (WIN32)

或

if (UNIX)
    #do something
endif (UNIX)

或

if (MSVC)
    #do something
endif (MSVC)

或类似

见CMake Useful Variables 和CMake Checking Platform

Answer 2

鉴于这是一个常见的问题，geronto-posting：

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

CMake boolean logic docs

CMake platform names, etc.

Answer 3

一般情况

您可以像这样为多个操作系统检测和指定变量：

检测 Microsoft Windows

if(WIN32)
    # for Windows operating system in general
endif()

或者：

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

检测 Apple MacOS

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

检测 Unix 和 Linux

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

您的特定链接器问题

要解决您使用特定于 Windows 的 wsock32 库的问题，只需将其从其他系统中删除，如下所示：

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

Answer 4

你有一些来自CMAKE的特殊话，看看：

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

Answer 5

生成器表达式也是可能的：

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

这将在 Windows 上链接 libA、wsock32 和 libC，在 Linux 上链接 libA、libB 和 libC

CMake Generator Expressions

Answer 6

试试看：

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

您可以找到其他有用的变量here。

Answer 7

我想把它留在这里，因为我在使用 Android SDK 在 Windows 中为 Android 编译时遇到了这个问题。

CMake 区分 TARGET 和 HOST 平台。

我的目标是 Android，所以像 CMAKE_SYSTEM_NAME 这样的变量的值是“Android”，而这里另一个答案的变量 WIN32 没有定义。 但我想知道我的 HOST 系统是否是 Windows，因为在 Windows、Linux 或 IO 上编译时我需要做一些不同的事情。 为此，我使用了 CMAKE_HOST_SYSTEM_NAME，我发现它在任何地方都鲜为人知或提及，因为对于大多数人来说，TARGEt 和 HOST 是相同的，或者他们不在乎。

希望这对某个地方的人有所帮助...

Answer 8

现代 CMake 方式

避免使用WIN32、APPLE等。版主对official forum的回复摘录：

WIN32、APPLE、UNIX 等变量被“软”弃用 [...] CMAKE_SYSTEM_NAME 是我在 CMake 代码中使用的，PLATFORM_ID 在生成器表达式中是必需的.

CMAKE_SYSTEM_NAME 或 PLAFORM_ID 可以采用哪些可能的值？ Refer the source.

如何检测平台

使用STREQUAL:

if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
  # Linux-specific stuff
endif ()

如何检测多个平台

创建一个列表变量并使用IN_LIST:

set(OPENGL_PLATFORMS Linux Windows)
if (CMAKE_SYSTEM_NAME IN_LIST OPENGL_PLATFORMS)
  # platform-specific stuff e.g.
  find_package(OpenGL REQUIRED)
endif ()

生成器表达式

使用PLATFORM_ID:

target_link_libraries(TARGET_NAME PRIVATE
  $<$<PLATFORM_ID:Linux,Windows>:OpenGL::GL>)

旁白：生成器表达式只能在手册调用时使用。例如，target_link_libraries 的文档将其标注出来，而 set_target_properties 则没有。我想阅读CMake: set_target_properties fails with target defined by generator expression 以了解原因。

Answer 9

使用一些预处理器宏来检查它是在 windows 还是 linux 中。 例如

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

在构建命令中包含 -l$(LIB)。

您还可以指定一些命令行参数来区分两者。