如何实现 Async - Await 函数

Question

我正在尝试实现一个等待integer 返回值更新的串行端口接口。出于学习目的，我有一个 Async 函数从具有随机时间延迟的过程函数返回一个 integer。我包括了我在 cmets 中看到的错误。该函数似乎没有返回Integer，也没有GetAwaiter。

Private Sub btnSubMain_Click(sender As Object, e As EventArgs) Handles btnSubMain.Click
    Dim Answer As Integer
    Answer = SomeInteger() 'Value of type 'Task(of Integer)' cannot be converted to 'Integer'
End Sub

Public Async Function SomeInteger() As Task(Of Integer)
    Dim exampleInteger As Integer = Await AwaitedprocessAsync()  'Await requires that type 'Integer" 
    '                                                             have a suitable GetAwaiter method
    Return exampleInteger
End Function

Function AwaitedprocessAsync() As Integer
    Dim timeout As Integer = CInt(Rnd() * 100)
    Thread.Sleep(timeout)
    Return 34  'return some test integer
End Function

Answer 1

我猜你想使用 Async / Await 的原因是在不阻塞 UI 的情况下执行异步处理。但是您设置它的方式看起来无论如何都会阻止用户界面。这是一个示例，它演示了如何在不阻塞和阻塞的情况下调用方法

Private Async Sub btnSubMain_Click(sender As Object, e As EventArgs) Handles btnSubMain.Click
    Dim answer As Integer
    Try
        btnSubMain.Enabled = False
        ' async call, UI continues to run
        answer = Await SomeIntegerAsync()
    Finally
        btnSubMain.Enabled = True
    End Try
    MessageBox.Show(answer.ToString())

    Try
        btnSubMain.Enabled = False
        ' synchronous call, UI is blocked
        answer = SomeInteger()
    Finally
        btnSubMain.Enabled = True
    End Try
    MessageBox.Show(answer.ToString())
End Sub

Function SomeIntegerAsync() As Task(Of Integer)
    Return Task.Run(AddressOf SomeInteger)
End Function

Function SomeInteger() As Integer
    Thread.Sleep(5000)
    Return 34
End Function

首先要注意的是UI事件处理程序被标记为Async，所以等待是在那个方法中完成的。大多数人都清楚，您的意图是在不阻塞 UI 的情况下允许某些事情发生。由于它是这样标记的，它必须包含Await。我写了两个函数，一个返回一个任务并且名称中有 Async，另一个只返回整数，名称中没有 Async。

我在按钮点击处理程序中都调用了。第一次调用将允许 UI 在调用函数时平稳运行。您可以通过在单击后移动窗口来检查。第二个直接调用函数并阻塞UI。这是您可以遵循的基本设计。

您可以使用Task.Delay 对您的问题注释进行评论，但我认为休眠线程是模拟长时间运行的代码的好方法，您不想阻塞用户界面，因此作为演示是有意义的。