如何使用带有变量名的包

Question

我的最终目标是使用参数作为包。我无法得到一个简单的例子来工作。有没有办法将use 和$variable 作为我的包裹？

我的模块.pm

package MyModule;
use strict;
use warnings;
use parent 'Exporter'; # imports and subclasses Exporter

our $test="hello world\n";
our @EXPORT = qw($test);

程序.pl

#!/usr/bin/perl
use strict;
use warnings;

my $x = 'MyModule.pm';
eval "require $x";
MyModule->import;
print "$test\n";

错误

Global symbol "$test" requires explicit package name at ./program.pl line 8.
Execution of ./program.pl aborted due to compilation errors.

Answer 1

require 有两种语法；一个需要一个不带引号的包名（例如require Foo::Bar;），另一个需要一个产生文件名的表达式（例如require "Foo/Bar.pm";）。请注意，后者仍然搜索库目录，并在组件之间使用/，即使在使用其他路径分隔符的系统上也是如此。

你的：

my $x = 'MyModule.pm';
eval "require $x";

尝试评估代码require MyModule.pm 会混淆这两种形式并给出错误Bareword "pm" not allowed while "strict subs" in use（被评估捕获并放在$@ 中）。

所以要么只做my $x = 'MyModule';（并检查 eval 是否发现错误，以确保稳健性），要么只做：

my $x = 'MyModule.pm';
require $x;

（或eval { require $x }，如果您希望捕获错误）。

这仍然会在$test 上留下您的严格错误，因为$test 直到运行时才会导出，并且严格检查是在编译时；要解决这个问题，您需要能够在编译时执行您的要求：

#!/usr/bin/perl
use 5.014;
use warnings;

BEGIN {
    my $x = 'MyModule';
    my $filename = "$x.pm" =~ s!::!/!gr;
    require $filename;
    $x->import;
}
say $test;