Javascript - 从字符串解析多项式[关闭]

Question

我刚刚问了这个问题，用于objective-c here，但需要快速得到答案，并且能够在objective-c 或javascript 中进行解析，所以我会在这里问js。

在我的应用程序中，用户将输入一个数学表达式作为字符串，例如n*3/7+9-5，我需要能够从该字符串中获取多项式，例如4, 3/7, 0, 0, 0, 0，有没有办法做到这一点或将在 javascript 中执行此操作的库？我正在使用节点，所以最好是节点兼容的东西。

我在google上做了一些研究，但似乎什么都没有，我不知道如何自己写。

Answer 1

你也可以在网上写 jison grammer http://zaach.github.io/jison/try/

计算器语法是这样的，我也在学这个有点难理解

来自http://zaach.github.io/jison/try/：

/* description: Parses end executes mathematical expressions. */

/* lexical grammar */
%lex
%%

\s+                   /* skip whitespace */
[0-9]+("."[0-9]+)?\b  return 'NUMBER'
"*"                   return '*'
"/"                   return '/'
"-"                   return '-'
"+"                   return '+'
"^"                   return '^'
"!"                   return '!'
"%"                   return '%'
"("                   return '('
")"                   return ')'
"PI"                  return 'PI'
"E"                   return 'E'
<<EOF>>               return 'EOF'
.                     return 'INVALID'

/lex

/* operator associations and precedence */

%left '+' '-'
%left '*' '/'
%left '^'
%right '!'
%right '%'
%left UMINUS

%start expressions

%% /* language grammar */

expressions
    : e EOF
        { typeof console !== 'undefined' ? console.log($1) : print($1);
          return $1; }
    ;

e
    : e '+' e
        {$$ = $1+$3;}
    | e '-' e
        {$$ = $1-$3;}
    | e '*' e
        {$$ = $1*$3;}
    | e '/' e
        {$$ = $1/$3;}
    | e '^' e
        {$$ = Math.pow($1, $3);}
    | e '!'
        {{
          $$ = (function fact (n) { return n==0 ? 1 : fact(n-1) * n })($1);
        }}
    | e '%'
        {$$ = $1/100;}
    | '-' e %prec UMINUS
        {$$ = -$2;}
    | '(' e ')'
        {$$ = $2;}
    | NUMBER
        {$$ = Number(yytext);}
    | E
        {$$ = Math.E;}
    | PI
        {$$ = Math.PI;}
    ;