使用 Enum.map 创建键映射

Question

简单的问题，我有这两张地图

[{"Africa", 1}, {"America", 2}, {"Europe", 3}]

[{"Congo", 1, 1}, {"France", 2, 3}, {"Spain", 3, 3}, {"USA", 4, 2}, {"Egypt", 5, 1}]

我想使用 Enum.map 和 Enum.filter 得到以下结果

[
  Africa: [{"Congo", 1}, {"Egypt", 1}],
  America: [{"USA", 4}],
  Europe: [{"France", 2}, {"Spain", 3}]
]

我尝试了以下组合，但没有得到预期的结果。可以帮忙吗？

Enum.map(
  [{"Africa", 1}, {"America", 2}, {"Europe", 3}],
  fn {continent_name, continent_id} ->
    Enum.filter(
      [{"Congo", 1, 1}, {"France", 2, 3}, {"Spain", 3, 3}, {"USA", 4, 2}, {"Egypt", 5, 1}],
      fn {country_name, country_id, country_continent_id} ->
        if continent_id == country_continent_id do
          [continent_name: [{country_name, country_id}]]
        end
      end
    )
  end
)

Answer 1

我想使用Enum.group_by/3

iex()> cons = [{"Africa", 1}, {"America", 2}, {"Europe", 3}]
iex()> countries = [{"Congo", 1, 1}, {"France", 2, 3}, {"Spain", 3, 3}, {"USA", 4, 2}, {"Egypt", 5, 1}]
iex()> countries = Enum.group_by(countries, fn {_, _, group_key} -> group_key end, fn {country, val, _} -> {country, val} end) |> Enum.into([])
[
  {1, [{"Congo", 1}, {"Egypt", 5}]},
  {2, [{"USA", 4}]},
  {3, [{"France", 2}, {"Spain", 3}]}
]
iex()> for {con, key_to_match} <- cons, {k, grouped_country} <- countries, key_to_match == k do
...()> [{String.to_atom(con), grouped_country}]
...()> end
[
  [Africa: [{"Congo", 1}, {"Egypt", 5}]],
  [America: [{"USA", 4}]],
  [Europe: [{"France", 2}, {"Spain", 3}]]
]

Answer 2

这是我的尝试：

continents =
  [{"Africa", 1}, {"America", 2}, {"Europe", 3}]
  |> Map.new(fn {a, b} -> {b, String.to_atom(a)} end)

[
  {"Congo", 1, 1},
  {"France", 2, 3},
  {"Spain", 3, 3},
  {"USA", 4, 2},
  {"Egypt", 5, 1}
]
|> Enum.group_by(&elem(&1, 2), &Tuple.delete_at(&1, 2))
|> Enum.map(fn {id, list} -> {continents[id], list} end)

输出：

[
  Africa: [{"Congo", 1}, {"Egypt", 5}],
  America: [{"USA", 4}],
  Europe: [{"France", 2}, {"Spain", 3}]
]

Answer 3

Kernel.SpecialForms.for/1 理解被严重低估了。这可能是最简单的方法。

(for {ct, cti} <- continents,
     {cy, cyi, cycti} <- countries, cti == cycti,
  do: {String.to_atom(ct), {cy, cyi}})
|> Enum.reduce([], fn {k, v}, acc ->
  Keyword.update(acc, k, [v], fn l -> [v | l] end)
end)

#⇒ [
#    Africa: [{"Egypt", 5}, {"Congo", 1}],
#    America: [{"USA", 4}],
#    Europe: [{"Spain", 3}, {"France", 2}]
#  ]

第一步，我们遍历大陆，然后通过国家和按大陆过滤国家就地。

Answer 4

这不使用过滤器，但让我知道这是否适合你。

continents = [{"Africa", 1}, {"America", 2}, {"Europe", 3}]
countries = [{"Congo", 1, 1}, {"France", 2, 3}, {"Spain", 3, 3}, {"USA", 4, 2}, {"Egypt", 5, 1}]

##Place countries by continent id in a map
countries_by_continent = Enum.reduce(countries,%{}, fn({name, country_id, continent_id}, countries_map) ->
  case Map.get(countries_map, continent_id) do
    nil ->   Map.put(countries_map, continent_id, [{name, country_id}])
    current_countries -> Map.put(countries_map, continent_id, current_countries ++ [{name, country_id}])
  end
end)

Enum.map(continents, fn({continent_name, continent_id}) ->
  ["#{continent_name}": Map.get(countries_by_continent, continent_id)]
end)