使用现代 OpenGL 衰减点精灵大小

Question

我正在尝试使用 OpenGL 3+ 使用点精灵来渲染一些粒子。我刚刚意识到我的观点存在重大问题。它们的大小会根据相机距离自动增加。结果如下：

接近粒子发射器：

而当距离很远时，一切都显得模糊而臃肿：

在旧版本中，似乎可以使用glPointParameter 调整磅值。该函数在新的 3+ OpenGL 中仍然可用，但它只支持两个参数。 GL_POINT_FADE_THRESHOLD_SIZE 似乎是我需要的，但我已经尝试过了，但没有结果。我也在使用glEnable(GL_PROGRAM_POINT_SIZE);

还有其他方法可以避免根据相机距离自动缩放点吗？我宁愿不必更改代码来使用由三角形制成的标准广告牌。

目前不确定是否相关，但这是我正在使用的顶点着色器：

layout(location = 0) in vec4 a_position_size; // Point size in w coord
layout(location = 1) in vec4 a_color;         // RGBA color modulated with texture

layout(location = 0) out vec4 v_color;

uniform mat4 u_MVPMatrix;

void main()
{
    gl_Position  = u_MVPMatrix * vec4(a_position_size.xyz, 1.0);
    gl_PointSize = a_position_size.w;
    v_color      = a_color;
}

Answer 1

原来我的问题是由于我对gl_PointSize的误解。正如 cmets 中所述并在文档中明确说明，gl_PointSize 包含光栅化点的大小，以像素为单位。因此，当我们远离点精灵时，它们看起来会更大，但这并不是因为它们被缩放了，而是因为它们仍然占据相同的屏幕空间，而 3D 场景的其余部分正在根据透视投影被缩小。

我通过对顶点着色器进行一些调整以根据与观察者的距离实际缩放点大小来解决问题：

uniform mat4 u_MVPMatrix;
uniform vec3 u_cameraPos;

// Constants (tweakable):
const float minPointScale = 0.1;
const float maxPointScale = 0.7;
const float maxDistance   = 100.0;

void main()
{
    // Calculate point scale based on distance from the viewer
    // to compensate for the fact that gl_PointSize is the point
    // size in rasterized points / pixels.
    float cameraDist = distance(a_position_size.xyz, u_cameraPos);
    float pointScale = 1.0 - (cameraDist / maxDistance);
    pointScale = max(pointScale, minPointScale);
    pointScale = min(pointScale, maxPointScale);

    // Set GL globals and forward the color:
    gl_Position  = u_MVPMatrix * vec4(a_position_size.xyz, 1.0);
    gl_PointSize = a_position_size.w * pointScale;
    v_color      = a_color;
}

Answer 2

在使用 GLSL 和 three.js 时遇到了同样的问题。根据glampert的回答解决了它，但首先three.js需要使用某些predefined variable names：

uniform vec4 origin;

void main() {
    vec4 mvPosition = modelViewMatrix * vec4( position, 1.0 );
    float cameraDist = distance( mvPosition, origin );
    gl_PointSize = 200.0 / cameraDist;
    gl_Position = projectionMatrix * mvPosition;
}

其次要注意，modelViewMatrix首先应用于粒子位置，然后计算到该位置的距离。因为如果您对粒子系统对象应用变换，您的粒子位于不等于全局坐标的对象坐标中。所以我计算视图坐标中的距离（相机始终在原点）。