【问题标题】:Calling Java new with a list of constructor args instead of args themselves (in Clojure)使用构造函数 args 列表而不是 args 本身调用 Java new(在 Clojure 中)
【发布时间】:2014-07-14 04:34:44
【问题描述】:

我知道我可以在 Clojure 中实例化这样的 Java 类:

(new Classname args*)

假设我收到了构造函数使用的参数的列表。那我该如何实例化这个类呢?我不能使用apply,因为new 不是函数。

【问题讨论】:

    标签: constructor clojure new-operator


    【解决方案1】:

    有两种基本方法:

    1. 反思:

      (clojure.lang.Reflector/invokeConstructor Klass (to-array [arg ...]))
      

      缓慢,但完全动态。

    2. 事先解包参数:

      (let [[arg1 arg2 ...] args]
        (Klass. arg1 arg2 ...))
      

      ((Klass. ...) 是写(new Klass ...) 的惯用方式;它在宏扩展时转换为后一种形式。)

      如果编译器可以推断出将使用哪个构造函数,这将会更快(您可能需要提供适当的类型提示 -- 使用 (set! *warn-on-reflection* true) 来查看是否正确)。

    当然,第二种方法有点笨拙。如果您希望在代码中的很多地方构造大量 Klass 实例,您可以编写适当的工厂函数。如果您希望以这种方式处理许多类,您可以抽象出定义工厂函数的过程:

    (defmacro deffactory [fname klass arg-types]
      (let [params (map (fn [t]
                          (with-meta (gensym) {:tag t}))
                        arg-types)]
        `(defn ~(with-meta fname {:tag klass}) ~(vec params)
           (new ~klass ~@params))))
    

    最后,如果定义工厂函数的过程本身需要完全动态,你可以做类似 Chouser 对this question 的第二种方法:定义一个函数而不是一个宏并让它eval 类似于语法-上面引用了(defn ...) 形式(语法引用= 前面带有反引号;我不确定如何在SO 帖子中包含文字反引号),除非您要使用fn 而不是defn并可能跳过fname。对编译器的调用会很昂贵,但返回的函数将像任何 Clojure 函数一样执行;请参阅 Chouser 的上述答案以获得稍长的讨论。

    为了完整起见,如果您使用的是 Clojure 1.3 或更高版本,并且所涉及的 Java 类实际上是一个 Clojure 记录,那么将已经在 ->RecordName 的名称下创建了一个位置工厂函数。

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2021-11-04
      • 1970-01-01
      • 2013-12-11
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多