在列中查找重复项并使用替代颜色突出显示行背景颜色

Question

1. 我想突出显示行的单元格颜色（文本在“A”列到 当“A”列中的值相同并且想要时，“G”）具有相同的颜色 对所有行重复相同的操作并应用其他颜色。
2. 还想将 2 个单元格中的字体颜色更改为红色（“F”列和 "G") 当“F”列中有“文件在 EMEA 服务器上”文本时。

Answer 1

此宏在 2 种颜色之间交替，随着 A 列中的值变化而变化。

Sub Highlighting()

Dim rw As Long
Dim lastrw As Long

' Define 2 different highlighting colours by their RGB values
Dim col1 As Long
Dim col2 As Long
col1 = RGB(255, 230, 180)
col2 = RGB(180, 230, 255)
' "Current" colour for highlighting
Dim col As Long
col = col1

With ThisWorkbook.ActiveSheet
    ' Get last row by last non-empty cell in column A
    lastrw = .Cells(.Rows.Count, 1).End(xlUp).Row
    ' Cycle through column A
    For rw = 1 To lastrw
        ' Highlight row with current colour
        .Range("A" & rw & ":G" & rw).Interior.Color = col
        ' If column A value in next row is different, change colour
        If .Cells(rw + 1, 1).Value <> .Cells(rw, 1) Then
            ' Set to whichever colour it is not
            If col = col1 Then
                col = col2
            Else
                col = col1
            End If
        End If
    Next rw
End With

End Sub

之前：

之后：

在某些情况下，您应该能够将字体颜色更改为红色，方法是将您自己的条件 If .Range("F" & rw).Value = "Files ... " 等插入主 For 循环。