如何在 Emacs 中浏览最近的文件（不仅仅是文件名）？答案

【问题标题】：how to browse through recent files (not just filenames) in Emacs?如何在 Emacs 中浏览最近的文件（不仅仅是文件名）？
【发布时间】：2013-03-07 23:59:14
【问题描述】：

我使用一个名为buffer-stack 的 Emacs 库来分页浏览我当前打开的缓冲区。这很棒，因为它允许我排除像 Messages 这样无趣的缓冲区，并只浏览包含我创建的内容的缓冲区。我通过一个按键 A-right 浏览这些缓冲区。

我也使用 Ido-mode 来browse through the names of recently opened files。

但是，我希望不仅可以浏览文件名，还可以浏览实际文件，最好只需按一下键即可。

如何浏览最近打开的文件？

【问题讨论】：

那么我们如何在“浏览实际文件”中定义“浏览”？
访问缓冲区中的文件。因此，调用击键（例如 A-down）将打开最近打开的文件，再次调用它将访问下一个最近打开的文件，依此类推。

标签： emacs org-mode ido recent-file-list

【解决方案1】：

您可以为此使用helm-recentf 及其persistent-action。

您可以使用helm-recentf 选择最近的文件，如下所示。

您可以通过按Ctrl-z(persistent-action) 来查看文件内容。您按Ctrl-z，然后将其内容临时显示到另一个窗口（在本例中为上窗口）。

如果你了解helm，请看official document

【讨论】：

也可以开启helm-follow-mode C-c C-f自动浏览。

【解决方案2】：

这里有两种可能的解决方案（具体取决于您想要的用例）。

(defun zin/open-recent-file ()
  "Open the most recent currently closed file.

This will omit currently open files, instead it will retrieve the
next oldest file in recentf-list."
  (interactive)
  (let* ((count    0)
         (recent   recentf-list)
         (r-length (length recent))
         (buffers  (mapcar 'buffer-file-name (buffer-list))))
    ;; Compare next file on the list to open buffers, if open skip it.
    (while (member (nth count recent)
                   buffers)
      (setq count (1+ count))
      (if (= r-length count)
          (error "All recent buffers already open")))
    (find-file (nth count recent))))

(lexical-let ((recent-count 0))
  (defun zin/visit-recent-file ()
    "Visit files on the recentf-list in descending order.

This will work backwards through recentf-list visiting each file
in turn."
    (interactive)
    ;; If last command was not to cycle through the files, then start
    ;; back at the first in the list.
    (unless (eq last-command 'zin/visit-recent-file)
      (setq recent-count 0))
    ;; If current buffer is the current entry on the list, increment.
    (if (equal (buffer-file-name) (nth 0 recentf-list))
        (setq recent-count (1+ recent-count)))
    ;; Error if all entries have been processed
    (if (= recent-count (length recentf-list))
        (error "At oldest recent buffer"))
    ;; Open appropriate file.
    (find-file (nth recent-count recentf-list))))

第一个将通过最近文件列表 (recentf-list) 并打开下一个未打开的文件。第二个将使用recentf-list 循环到列表中的下一个缓冲区，直到所有内容都被访问然后出错（因为列表顺序会随着文件的重新打开而改变）。

要让它在到达终点时重新开始循环，只需将(error ...) 更改为

(setq recent-count 0)

【讨论】：